Version bump #526878 by Thomas Stein.

(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key D2E96200)

2 files changed, 101 insertions, 1 deletions

diff --git a/app-emulation/qemu-guest-agent/ChangeLog b/app-emulation/qemu-guest-agent/ChangeLog
index ed293207291c..b1cdcf710512 100644
--- a/app-emulation/qemu-guest-agent/ChangeLog
+++ b/app-emulation/qemu-guest-agent/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-emulation/qemu-guest-agent
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/qemu-guest-agent/ChangeLog,v 1.17 2014/05/18 17:15:42 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/qemu-guest-agent/ChangeLog,v 1.18 2014/10/26 08:37:09 vapier Exp $
+
+*qemu-guest-agent-2.1.2 (26 Oct 2014)
+
+  26 Oct 2014; Mike Frysinger <vapier@gentoo.org>
+  +qemu-guest-agent-2.1.2.ebuild:
+  Version bump #526878 by Thomas Stein.
 
 *qemu-guest-agent-2.0.0 (18 May 2014)
 
diff --git a/app-emulation/qemu-guest-agent/qemu-guest-agent-2.1.2.ebuild b/app-emulation/qemu-guest-agent/qemu-guest-agent-2.1.2.ebuild
new file mode 100644
index 000000000000..2f4762a54c83
--- /dev/null
+++ b/app-emulation/qemu-guest-agent/qemu-guest-agent-2.1.2.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/qemu-guest-agent/qemu-guest-agent-2.1.2.ebuild,v 1.1 2014/10/26 08:37:09 vapier Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_6,2_7} )
+
+inherit eutils systemd udev python-r1
+
+BACKPORTS=
+MY_PN="qemu"
+MY_P="${MY_PN}-${PV}"
+
+if [[ ${PV} = *9999* ]]; then
+	EGIT_REPO_URI="git://git.qemu.org/qemu.git"
+	inherit git-2
+else
+	SRC_URI="http://wiki.qemu.org/download/${MY_P}.tar.bz2
+		${BACKPORTS:+
+			http://dev.gentoo.org/~cardoe/distfiles/${MY_P}-${BACKPORTS}.tar.xz}"
+	KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
+fi
+
+DESCRIPTION="QEMU Guest Agent (qemu-ga) for use when running inside a VM"
+HOMEPAGE="http://wiki.qemu.org/Features/QAPI/GuestAgent"
+
+LICENSE="GPL-2 BSD-2"
+SLOT="0"
+IUSE=""
+
+RDEPEND=">=dev-libs/glib-2.22
+	!<app-emulation/qemu-1.1.1-r1
+	!<sys-apps/sysvinit-2.88-r5"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	[[ -n ${BACKPORTS} ]] && \
+		EPATCH_FORCE=yes EPATCH_SUFFIX="patch" EPATCH_SOURCE="${S}/patches" \
+			epatch
+
+	epatch_user
+}
+
+src_configure() {
+	python_export_best
+
+	tc-export AR LD OBJCOPY
+
+	./configure \
+		--prefix=/usr \
+		--sysconfdir=/etc \
+		--libdir="/usr/$(get_libdir)" \
+		--localstatedir=/ \
+		--disable-bsd-user \
+		--disable-linux-user \
+		--disable-system \
+		--disable-strip \
+		--disable-werror \
+		--enable-guest-agent \
+		--python="${PYTHON}" \
+		--cc="$(tc-getCC)" \
+		--cxx="$(tc-getCXX)" \
+		--host-cc="$(tc-getBUILD_CC)"
+}
+
+src_compile() {
+	emake V=1 qemu-ga
+}
+
+src_install() {
+	dobin qemu-ga
+
+	# Normal init stuff
+	newinitd "${FILESDIR}/qemu-ga.init-r1" qemu-guest-agent
+	newconfd "${FILESDIR}/qemu-ga.conf-r1" qemu-guest-agent
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}/qemu-ga.logrotate" qemu-guest-agent
+
+	# systemd stuff
+	udev_newrules "${FILESDIR}/qemu-ga-systemd.udev" 99-qemu-guest-agent.rules
+
+	systemd_newunit "${FILESDIR}/qemu-ga-systemd.service" \
+		qemu-guest-agent.service
+}
+
+pkg_postinst() {
+	elog "You should add 'qemu-guest-agent' to the default runlevel."
+	elog "e.g. rc-update add qemu-guest-agent default"
+}