Version bump, add a patch to fix 64bit platforms (from Fedora bug #435508)

Add compatibility with Linux and add ~amd64 keyword
(Portage version: 2.2_rc23/cvs/Linux x86_64)

1 files changed, 47 insertions, 0 deletions

diff --git a/app-backup/cpdup/cpdup-1.11.ebuild b/app-backup/cpdup/cpdup-1.11.ebuild
new file mode 100644
index 000000000000..ef880f42d2cd
--- /dev/null
+++ b/app-backup/cpdup/cpdup-1.11.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-backup/cpdup/cpdup-1.11.ebuild,v 1.1 2009/02/05 11:54:05 drizzt Exp $
+
+inherit eutils toolchain-funcs
+
+DESCRIPTION="A comprehensive filesystem mirroring program"
+HOMEPAGE="http://apollo.backplane.com/FreeSrc/"
+SRC_URI="http://apollo.backplane.com/FreeSrc/${P}.tgz"
+
+LICENSE="as-is"
+SLOT="0"
+KEYWORDS="~x86-fbsd ~amd64"
+IUSE="userland_GNU threads"
+
+DEPEND=""
+RDEPEND=""
+
+S="${WORKDIR}/${PN}"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	epatch "${FILESDIR}"/${P}-explicit_sizes.patch	# Patch from Fedora bug #435508
+	epatch "${FILESDIR}"/${P}-unused.patch
+
+	if use userland_GNU; then
+		cp "${FILESDIR}"/Makefile.linux Makefile
+		# bits/stat.h has __unused too
+		sed -i 's/__unused/__cpdup_unused/' *.c
+	fi
+	rm -r scripts/CVS
+}
+
+src_compile() {
+	tc-export CC
+	use threads || MAKEOPTS="$MAKEOPTS NOPTHREADS=1"
+	MAKE=make emake || die "emake failed"
+}
+
+src_install() {
+	dobin cpdup || die "cannot install cpdup"
+	doman cpdup.1
+	docinto scripts
+	dodoc scripts/*
+}