2 files changed, 77 insertions, 2 deletions
diff --git a/app-misc/dvtm/ChangeLog b/app-misc/dvtm/ChangeLog
index 056e3af2dbf8..0db81e3ec8a0 100644
--- a/app-misc/dvtm/ChangeLog
+++ b/app-misc/dvtm/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-misc/dvtm
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/dvtm/ChangeLog,v 1.16 2012/11/20 20:58:39 ago Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/dvtm/ChangeLog,v 1.17 2013/03/25 20:18:00 chithanh Exp $
+
+*dvtm-9999 (25 Mar 2013)
+
+  25 Mar 2013; Chí-Thanh Christopher Nguyễn <chithanh@gentoo.org>
+  +dvtm-9999.ebuild:
+  Add live ebuild, bug #456722.
 
   20 Nov 2012; Agostino Sarubbo <ago@gentoo.org> dvtm-0.8.ebuild:
   Stable for x86, wrt bug #441084
diff --git a/app-misc/dvtm/dvtm-9999.ebuild b/app-misc/dvtm/dvtm-9999.ebuild
new file mode 100644
index 000000000000..0389cf4f5804
--- /dev/null
+++ b/app-misc/dvtm/dvtm-9999.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/dvtm/dvtm-9999.ebuild,v 1.1 2013/03/25 20:18:00 chithanh Exp $
+
+EAPI=5
+
+inherit savedconfig toolchain-funcs
+
+DESCRIPTION="Dynamic virtual terminal manager"
+HOMEPAGE="http://www.brain-dump.org/projects/dvtm/"
+
+if [[ ${PV} == 9999* ]]; then
+	inherit git-2
+	EGIT_REPO_URI="git://repo.or.cz/dvtm.git"
+	KEYWORDS=""
+else
+	SRC_URI="http://www.brain-dump.org/projects/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="unicode"
+
+DEPEND="sys-libs/ncurses[unicode?]"
+RDEPEND=${DEPEND}
+
+src_prepare() {
+	sed -i \
+		-e 's|FLAGS =|FLAGS +=|' \
+		-e 's|-I/usr/local/include||' \
+		-e 's|-L/usr/local/lib||' \
+		-e 's|-Os||' \
+		config.mk || die "sed config.mk failed"
+	use unicode || {
+		sed -i \
+			-e 's|-lncursesw|-lncurses|' \
+			config.mk || die "sed config.mk failed"
+	}
+	sed -i \
+		-e '/strip/d' \
+		-e 's:@tic :@tic -o ${DESTDIR}${PREFIX}/share/terminfo :g' \
+		Makefile || die "sed Makefile failed"
+
+	restore_config config.h
+}
+
+src_compile() {
+	local msg=""
+	use savedconfig && msg=", please check the configfile"
+	emake CC=$(tc-getCC) ${PN} || die "emake failed${msg}"
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="/usr" install
+
+	insinto /usr/share/${PN}
+	newins config.h ${PF}.config.h
+
+	dodoc README
+
+	save_config config.h
+}
+
+pkg_postinst() {
+	elog "This ebuild has support for user defined configs"
+	elog "Please read this ebuild for more details and re-emerge as needed"
+	elog "if you want to add or remove functionality for ${PN}"
+}