From aa829dbe049d4e3d6417812ab6ca7274971e3a07 Mon Sep 17 00:00:00 2001
From: Tim Harder <radhermit@gentoo.org>
Date: Wed, 11 Feb 2015 01:30:47 +0000
Subject: Version bump (bug #536596).

(Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)
---
 app-misc/task/ChangeLog         |  9 ++++--
 app-misc/task/task-2.4.0.ebuild | 61 +++++++++++++++++++++++++++++++++++++++++
 2 files changed, 68 insertions(+), 2 deletions(-)
 create mode 100644 app-misc/task/task-2.4.0.ebuild

(limited to 'app-misc')

diff --git a/app-misc/task/ChangeLog b/app-misc/task/ChangeLog
index dcdb184ea2aa..8a8920b44100 100644
--- a/app-misc/task/ChangeLog
+++ b/app-misc/task/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-misc/task
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/task/ChangeLog,v 1.49 2014/11/28 18:00:46 radhermit Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/task/ChangeLog,v 1.50 2015/02/11 01:30:47 radhermit Exp $
+
+*task-2.4.0 (11 Feb 2015)
+
+  11 Feb 2015; Tim Harder <radhermit@gentoo.org> +task-2.4.0.ebuild:
+  Version bump (bug #536596).
 
 *task-2.3.0-r1 (28 Nov 2014)
 
diff --git a/app-misc/task/task-2.4.0.ebuild b/app-misc/task/task-2.4.0.ebuild
new file mode 100644
index 000000000000..3d1c5c2b8fbf
--- /dev/null
+++ b/app-misc/task/task-2.4.0.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/task/task-2.4.0.ebuild,v 1.1 2015/02/11 01:30:47 radhermit Exp $
+
+EAPI=5
+
+inherit eutils cmake-utils bash-completion-r1
+
+DESCRIPTION="Taskwarrior is a command-line todo list manager"
+HOMEPAGE="http://taskwarrior.org/"
+SRC_URI="http://taskwarrior.org/download/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86 ~x64-macos"
+IUSE="gnutls vim-syntax zsh-completion"
+
+DEPEND="sys-libs/readline
+	gnutls? ( net-libs/gnutls )
+	elibc_glibc? ( sys-apps/util-linux )"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	# use the correct directory locations
+	sed -i "s:/usr/local/bin:${EPREFIX}/usr/bin:" \
+		scripts/add-ons/* || die
+
+	# don't automatically install scripts
+	sed -i '/scripts/d' CMakeLists.txt || die
+
+	epatch "${FILESDIR}"/${PN}-2.3.0-gnutls-automagic.patch
+}
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use_use gnutls GNUTLS)
+		-DTASK_DOCDIR=share/doc/${PF}
+		-DTASK_RCDIR=share/${PN}/rc
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	newbashcomp scripts/bash/task.sh task
+
+	if use vim-syntax ; then
+		rm scripts/vim/README
+		insinto /usr/share/vim/vimfiles
+		doins -r scripts/vim/*
+	fi
+
+	if use zsh-completion ; then
+		insinto /usr/share/zsh/site-functions
+		doins scripts/zsh/*
+	fi
+
+	exeinto /usr/share/${PN}/scripts
+	doexe scripts/add-ons/*
+}
-- 
cgit v1.2.3-65-gdbad