From 729c85fffe5661fdbe0e7a7675181819ce720c8d Mon Sep 17 00:00:00 2001
From: Jeroen Roovers <jer@gentoo.org>
Date: Mon, 17 Nov 2014 14:06:30 +0000
Subject: Version bump.

(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key A792A613)
---
 dev-libs/liblinear/ChangeLog            |  7 ++++-
 dev-libs/liblinear/liblinear-196.ebuild | 53 +++++++++++++++++++++++++++++++++
 2 files changed, 59 insertions(+), 1 deletion(-)
 create mode 100644 dev-libs/liblinear/liblinear-196.ebuild

(limited to 'dev-libs/liblinear')

diff --git a/dev-libs/liblinear/ChangeLog b/dev-libs/liblinear/ChangeLog
index 7197b1d4c293..83c2d78e36dc 100644
--- a/dev-libs/liblinear/ChangeLog
+++ b/dev-libs/liblinear/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/liblinear
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/liblinear/ChangeLog,v 1.6 2014/08/21 12:45:10 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/liblinear/ChangeLog,v 1.7 2014/11/17 14:06:30 jer Exp $
+
+*liblinear-196 (17 Nov 2014)
+
+  17 Nov 2014; Jeroen Roovers <jer@gentoo.org> +liblinear-196.ebuild:
+  Version bump.
 
   21 Aug 2014; Raúl Porcel <armin76@gentoo.org> liblinear-194.ebuild:
   Add ~alpha/~ia64/~s390/~sh/~sparc wrt #512546
diff --git a/dev-libs/liblinear/liblinear-196.ebuild b/dev-libs/liblinear/liblinear-196.ebuild
new file mode 100644
index 000000000000..dfb9a96d0736
--- /dev/null
+++ b/dev-libs/liblinear/liblinear-196.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/liblinear/liblinear-196.ebuild,v 1.1 2014/11/17 14:06:30 jer Exp $
+
+EAPI=5
+inherit multilib toolchain-funcs
+
+DESCRIPTION="A Library for Large Linear Classification"
+HOMEPAGE="http://www.csie.ntu.edu.tw/~cjlin/liblinear/ https://github.com/cjlin1/liblinear"
+SRC_URI="https://github.com/cjlin1/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~s390 ~sh ~sparc ~x86"
+
+# /usr/bin/predict collision
+RDEPEND="!sci-astronomy/predict"
+
+src_prepare() {
+	sed -i \
+		-e '/^AR/s|=|?=|g' \
+		-e '/^RANLIB/s|=|?=|g' \
+		-e '/^CFLAGS/d;/^CXXFLAGS/d' \
+		blas/Makefile || die
+	sed -i \
+		-e 's|make|$(MAKE)|g' \
+		-e '/$(LIBS)/s|$(CFLAGS)|& $(LDFLAGS)|g' \
+		-e '/^CFLAGS/d;/^CXXFLAGS/d' \
+		-e 's|$${SHARED_LIB_FLAG}|& $(LDFLAGS)|g' \
+		Makefile || die
+}
+
+src_compile() {
+	CC=$(tc-getCC) \
+		CXX=$(tc-getCXX) \
+		CFLAGS="${CFLAGS} -fPIC" \
+		CXXFLAGS="${CXXFLAGS} -fPIC" \
+		AR="$(tc-getAR) rcv" \
+		RANLIB="$(tc-getRANLIB)" \
+		emake lib all
+}
+
+src_install() {
+	dolib ${PN}.so.2
+	dosym ${PN}.so.2 /usr/$(get_libdir)/${PN}.so
+
+	dobin predict train
+
+	insinto /usr/include
+	doins linear.h
+
+	dodoc README
+}
-- 
cgit v1.2.3-65-gdbad