From 33759877ed4d7cd9c04b33edb3e36672fcd7744c Mon Sep 17 00:00:00 2001
From: Michael Sterrett <mr_bones_@gentoo.org>
Date: Thu, 30 Dec 2010 09:08:09 +0000
Subject: version bump

(Portage version: 2.1.9.25/cvs/Linux i686)
---
 dev-libs/zziplib/ChangeLog              |  8 +++-
 dev-libs/zziplib/zziplib-0.13.60.ebuild | 65 +++++++++++++++++++++++++++++++++
 2 files changed, 72 insertions(+), 1 deletion(-)
 create mode 100644 dev-libs/zziplib/zziplib-0.13.60.ebuild

(limited to 'dev-libs')

diff --git a/dev-libs/zziplib/ChangeLog b/dev-libs/zziplib/ChangeLog
index b2f58157124b..95dc7694972b 100644
--- a/dev-libs/zziplib/ChangeLog
+++ b/dev-libs/zziplib/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/zziplib
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/zziplib/ChangeLog,v 1.87 2010/09/28 16:49:40 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/zziplib/ChangeLog,v 1.88 2010/12/30 09:08:08 mr_bones_ Exp $
+
+*zziplib-0.13.60 (30 Dec 2010)
+
+  30 Dec 2010; Michael Sterrett <mr_bones_@gentoo.org>
+  +zziplib-0.13.60.ebuild:
+  version bump
 
   28 Sep 2010; Brent Baude <ranger@gentoo.org> zziplib-0.13.59-r1.ebuild:
   stable ppc, bug 328131
diff --git a/dev-libs/zziplib/zziplib-0.13.60.ebuild b/dev-libs/zziplib/zziplib-0.13.60.ebuild
new file mode 100644
index 000000000000..d8a1c1f25cc7
--- /dev/null
+++ b/dev-libs/zziplib/zziplib-0.13.60.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/zziplib/zziplib-0.13.60.ebuild,v 1.1 2010/12/30 09:08:09 mr_bones_ Exp $
+
+EAPI="2"
+inherit libtool eutils flag-o-matic
+
+DESCRIPTION="Lightweight library used to easily extract data from files archived in a single zip file"
+HOMEPAGE="http://zziplib.sourceforge.net/"
+SRC_URI="mirror://sourceforge/zziplib/${P}.tar.bz2"
+
+LICENSE="|| ( LGPL-2.1 MPL-1.1 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~x64-freebsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc sdl static-libs test"
+
+RDEPEND="sys-libs/zlib
+	sdl? ( >=media-libs/libsdl-1.2.6 )"
+DEPEND="${RDEPEND}
+	>=dev-lang/python-2.4
+	dev-util/pkgconfig
+	test? ( app-arch/zip )"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-0.13.49-SDL-test.patch
+
+	# zziplib tries to install backwards compat symlinks we dont want
+	sed -i -e '/^zzip-postinstall:/s|$|\ndisable-this:|' Makefile.in || die
+	sed -i -e '/^install-exec-hook:/s|$|\ndisable-this:|' zzip/Makefile.in || die
+
+	elibtoolize
+}
+
+src_configure() {
+	append-flags -fno-strict-aliasing # bug reported upstream
+	export ac_cv_path_XMLTO= # man pages are bundled in .tar's
+	econf \
+		--disable-dependency-tracking \
+		$(use_enable sdl) \
+		$(use_enable static-libs static)
+}
+
+src_test() {
+	# need this because `make test` will always return true
+	# tests fail with -j > 1 (bug #241186)
+	emake -j1 check || die
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+	# fowners fails when we don't have enough permissions (Prefix)
+	if [[ ${EUID} == 0 ]] ; then
+		fowners -R root /usr/share/man || die #321975
+	fi
+
+	if ! use static-libs ; then
+		find "${D}" -type f -name '*.la' -exec rm {} + || die
+	fi
+
+	dodoc ChangeLog README TODO
+
+	if use doc ; then
+		dohtml -r docs/* || die 'dohtml failed'
+	fi
+}
-- 
cgit v1.2.3-65-gdbad