From 7d564fb325b0eb03df7e3a97f04f3f03f14b5893 Mon Sep 17 00:00:00 2001
From: Naohiro Aota <naota@gentoo.org>
Date: Fri, 14 Oct 2011 00:49:53 +0000
Subject: Version bumped.

(Portage version: 2.2.0_alpha64/cvs/Linux x86_64)
---
 dev-util/global/ChangeLog         |  7 +++-
 dev-util/global/global-6.1.ebuild | 72 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 78 insertions(+), 1 deletion(-)
 create mode 100644 dev-util/global/global-6.1.ebuild

(limited to 'dev-util/global')

diff --git a/dev-util/global/ChangeLog b/dev-util/global/ChangeLog
index c455bb0dd616..acce640d7c24 100644
--- a/dev-util/global/ChangeLog
+++ b/dev-util/global/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/global
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/global/ChangeLog,v 1.92 2011/09/17 16:21:57 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/global/ChangeLog,v 1.93 2011/10/14 00:49:53 naota Exp $
+
+*global-6.1 (14 Oct 2011)
+
+  14 Oct 2011; Naohiro Aota <naota@gentoo.org> +global-6.1.ebuild:
+  Version bumped.
 
   17 Sep 2011; Pacho Ramos <pacho@gentoo.org> metadata.xml:
   Add Arfrever as proxy maintainer as requested by him.
diff --git a/dev-util/global/global-6.1.ebuild b/dev-util/global/global-6.1.ebuild
new file mode 100644
index 000000000000..b72501ff2a6d
--- /dev/null
+++ b/dev-util/global/global-6.1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/global/global-6.1.ebuild,v 1.1 2011/10/14 00:49:53 naota Exp $
+
+EAPI="4"
+
+inherit elisp-common
+
+DESCRIPTION="GNU Global is a tag system to find the locations of a specified object in various sources."
+HOMEPAGE="http://www.gnu.org/software/global/global.html"
+SRC_URI="ftp://ftp.gnu.org/pub/gnu/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86 ~x86-fbsd"
+IUSE="doc emacs vim"
+
+RDEPEND="emacs? ( virtual/emacs )
+	vim? ( || ( app-editors/vim app-editors/gvim ) )"
+DEPEND="${DEPEND}
+	doc? ( app-text/texi2html sys-apps/texinfo )"
+
+SITEFILE="50gtags-gentoo.el"
+
+src_configure() {
+	econf "$(use_with emacs lispdir "${SITELISP}/${PN}")"
+}
+
+src_compile() {
+	if use doc; then
+		texi2pdf -q -o doc/global.pdf doc/global.texi
+		texi2html -o doc/global.html doc/global.texi
+	fi
+
+	if use emacs; then
+		elisp-compile *.el || die "elisp-compile failed"
+	fi
+
+	emake
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	if use doc; then
+		dohtml doc/global.html
+		[[ -f doc/global.pdf ]] && dodoc doc/global.pdf
+	fi
+
+	dodoc AUTHORS FAQ NEWS README THANKS
+
+	insinto /etc
+	doins gtags.conf
+
+	if use vim; then
+		insinto /usr/share/vim/vimfiles/plugin
+		doins gtags.vim
+	fi
+
+	if use emacs; then
+		elisp-install ${PN} *.{el,elc} || die "elisp-install failed"
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}" || die "elisp-site-file-install failed"
+	fi
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}
-- 
cgit v1.2.3-65-gdbad