# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/fontconfig-infinality/fontconfig-infinality-20130404.ebuild,v 1.1 2013/04/05 08:58:58 yngwin Exp $

EAPI=5
inherit readme.gentoo

DESCRIPTION="Configuration to be used in conjunction with the freetype-infinality subpixel hinting"
HOMEPAGE="http://www.infinality.net/blog/infinality-freetype-patches/"
SRC_URI="http://dev.gentoo.org/~yngwin/distfiles/${P}.tar.xz
	nyx? ( http://dev.gentoo.org/~yngwin/distfiles/fontconfig-nyx-2.tar.xz )"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+nyx"

DEPEND=""
RDEPEND="app-admin/eselect-fontconfig
	app-admin/eselect-infinality
	app-admin/eselect-lcdfilter
	>=x11-libs/libXft-2.3.0
	nyx? ( media-fonts/croscorefonts )"
PDEPEND="media-libs/freetype:2[infinality]"

DOC_CONTENTS="Use eselect fontconfig enable 52-infinality.conf to enable the
configuration. Then use eselect infinality to set your fontconfig style and
eselect lcdfilter to set freetype variables. If you run into trouble with
applications not being able to find Type-1 fonts, then comment out the
relevant lines in /etc/fonts/infinality/infinality.conf"

src_configure() {
	:
}

src_compile() {
	:
}

src_install() {
	dodoc infinality/{CHANGELOG,CHANGELOG.pre_git,README}
	readme.gentoo_create_doc

	insinto /etc/fonts/conf.avail
	doins conf.avail/52-infinality.conf

	insinto /etc/fonts/infinality
	doins -r infinality/{conf.src,styles.conf.avail,infinality.conf}

	insinto /etc/X11/
	doins "${FILESDIR}"/Xresources

	if use nyx ; then
		insinto /etc/fonts/infinality/styles.conf.avail
		doins -r "${WORKDIR}"/nyx
	fi
}