kde-apps/ktp-accounts-kcm: 22.03.80 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 64 insertions, 0 deletions

diff --git a/kde-apps/ktp-accounts-kcm/Manifest b/kde-apps/ktp-accounts-kcm/Manifest
new file mode 100644
index 0000000000..d0f05d73ba
--- /dev/null
+++ b/kde-apps/ktp-accounts-kcm/Manifest
@@ -0,0 +1 @@
+DIST ktp-accounts-kcm-22.03.80.tar.xz 266480 BLAKE2B 0f289a0491b8d7d4e2158e1069fc6921b5a1b91a9ecdde02b10864e478608c32efc2aab65269a0e0552bcad1f108601e36bf7670895dceaa6b8d5f6fab354690 SHA512 9b0d6b2706c93518d432e834a0b1378959e2aa7667a15e2f47c4be8a80be9c251adde5974e713e874baaa4c416f27188663a9c73d96512e25c47555f6365f7e8
diff --git a/kde-apps/ktp-accounts-kcm/ktp-accounts-kcm-22.03.80.ebuild b/kde-apps/ktp-accounts-kcm/ktp-accounts-kcm-22.03.80.ebuild
new file mode 100644
index 0000000000..eea1b79573
--- /dev/null
+++ b/kde-apps/ktp-accounts-kcm/ktp-accounts-kcm-22.03.80.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.92.0
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="KDE Telepathy account management kcm"
+HOMEPAGE="https://community.kde.org/KTp"
+
+LICENSE="LGPL-2.1"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="experimental"
+
+COMMON_DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/kaccounts-integration-${PVCUT}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	net-libs/accounts-qt
+	net-libs/signond
+	>=net-libs/telepathy-qt-0.9.8
+"
+DEPEND="${COMMON_DEPEND}
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	net-libs/libaccounts-glib
+"
+RDEPEND="${COMMON_DEPEND}
+	>=kde-apps/kaccounts-providers-${PVCUT}:5
+	net-im/telepathy-connection-managers
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_DISABLED_PROVIDERS=$(usex experimental)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	if use experimental; then
+		ewarn "Experimental providers are enabled."
+		ewarn "Most of them aren't integrated nicely and may require additional steps for account creation."
+		ewarn "Use at your own risk!"
+	fi
+	ecm_pkg_postinst
+}