# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"

inherit eutils bzr

EBZR_REVISION="1877"
EBZR_REPO_URI="http://bazaar.launchpad.net/~ltsp-upstream/ltsp/ltsp-trunk"

DESCRIPTION="LTSP client scripts"
HOMEPAGE="http://www.ltsp.org/"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 x86"
IUSE=""

# note on dependencies
# joystick for inputattach (serial devices)
# run-mailcap for ltsp-remoteapps
# numlockx for X_NUMLOCK
# lsb-release for server ltsp-info
DEPEND="sys-devel/bison
	sys-devel/flex"
RDEPEND="!net-misc/ltsp-server
	media-sound/pulseaudio
	>=sys-fs/ltspfs-0.5.0
	net-analyzer/netcat
	net-misc/openssh
	sys-block/nbd
	sys-apps/lsb-release
	net-ftp/tftp-hpa
	>=sys-fs/sshfs-fuse-2.1
	sys-apps/iproute2
	games-util/joystick
	media-sound/alsa-utils
	media-plugins/alsa-plugins
	app-misc/run-mailcap
	net-misc/ntp
	x11-misc/numlockx
	x11-apps/xrandr
	x11-apps/xprop"

src_unpack() {
	bzr_src_unpack
}

src_prepare() {
	epatch "${FILESDIR}/${P}-ltsdownloadarch.patch"
	epatch "${FILESDIR}/${P}-setupconfd.patch"
}

src_configure() {
	pushd client/getltscfg
	emake || die "Could not make getltspcfg"
	popd

	pushd localapps
	./autogen.sh || die "Could not generate configure for xatomwait"
	econf || die "Could not configure xatomwait"
	emake || die "Could not make xatomwait"
	popd
}

src_install() {
	ltspdir="/usr/share/ltsp"

	dobin client/getltscfg/getltscfg
	dosbin client/jetpipe/jetpipe

	dobin localapps/ltsp-localappsd
	dobin localapps/ltsp-genmenu
	dobin localapps/ltsp-remoteapps
	dobin localapps/ltsp-remoteappsd
	dobin localapps/ltsp-open
	dobin localapps/src/xatomwait

	dodir /var/lib/ltsp-client-setup
	dodir /var/cache/ltsp
	dodir /var/cache/ltsp-localapps

	exeinto ${ltspdir}
	doexe client/configure-x.sh
	doexe client/screen_session
	doexe client/update-kernels
	doexe client/xinitrc

	exeinto ${ltspdir}/screen.d
	doexe client/screen.d/*

	insinto ${ltspdir}
	doins ltsp-common-functions
	doins client/ltsp_config
	doins client/screen-x-common
	doins client/initscripts/ltsp-init-common

	insinto ${ltspdir}/xinitrc.d
	doins client/xinitrc.d/*

	insinto ${ltspdir}/screen-session.d
	doins client/screen-session.d/*

	insinto /usr/share/ldm/rc.d
	doins localapps/ldm-rc.d/*

	newinitd client/initscripts/Gentoo/ltsp-client-setup.initd ltsp-client-setup
	newinitd client/initscripts/Gentoo/ltsp-client.initd ltsp-client
	newconfd client/initscripts/Gentoo/ltsp-client-setup.confd ltsp-client-setup

	doman client/jetpipe/jetpipe.8
	doman client/getltscfg/getltscfg.1
	doman localapps/doc/xatomwait.1
	doman localapps/doc/ltsp-localappsd.1
	doman localapps/doc/ltsp-genmenu.1
	doman localapps/doc/ltsp-remoteapps.1

	cp "${FILESDIR}/lts.conf" "${D}/etc/lts.conf"
}