app-backup/dar: add 2.7.4

Signed-off-by: Viorel Munteanu <ceamac.paragon@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/24575
Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

2 files changed, 92 insertions, 0 deletions

diff --git a/app-backup/dar/Manifest b/app-backup/dar/Manifest
index e678e24905c9..df74e66e9379 100644
--- a/app-backup/dar/Manifest
+++ b/app-backup/dar/Manifest
@@ -1 +1,2 @@
 DIST dar-2.7.3.tar.gz 2398624 BLAKE2B 9d34d233968efcd390db6a1afa1bb93477b6dcbb4bb8c6beb315e927f7ae624bdf23b77f32233a63e3ddd437701fbbd1ee19e5c7ab4f0366ef7e646bacdab46c SHA512 a8a930cd39cae66199e402e61fc48609fe22b821c12407ab7922b8bc8f43f9b11b2f0732baf8198b41d193442a1f82d18536a0d6a7fd7282aaed3600342c7d48
+DIST dar-2.7.4.tar.gz 2404731 BLAKE2B a3b8cb2049f1b12048023916e2951ca9efc57791afa62df58ceb796f69503c9d2795e0b6e11f2b3efdde51f2e0f78e972a7e08742f2278f92231db94a21dfbbe SHA512 fcdf222c4244d02797dff06797a67baefd1b7bdd409ed09da05e23430b025b1cc66ee98e85aa43b481ec3d17a84b7c2bbcebe4c8f23a2a480146845d3da93477
diff --git a/app-backup/dar/dar-2.7.4.ebuild b/app-backup/dar/dar-2.7.4.ebuild
new file mode 100644
index 000000000000..ef7cc64225b7
--- /dev/null
+++ b/app-backup/dar/dar-2.7.4.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic
+
+DESCRIPTION="A full featured backup tool, aimed for disks"
+HOMEPAGE="http://dar.linux.free.fr/"
+SRC_URI="mirror://sourceforge/dar/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86 ~amd64-linux"
+IUSE="argon2 curl dar32 dar64 doc gcrypt gpg lz4 lzo nls rsync threads xattr"
+
+REQUIRED_USE="?? ( dar32 dar64 )
+		gpg? ( gcrypt )"
+
+RESTRICT="test" # need to be run as root
+
+RDEPEND="
+	app-arch/bzip2:=
+	app-arch/xz-utils
+	app-arch/zstd:=
+	sys-libs/libcap
+	>=sys-libs/zlib-1.2.3:=
+	argon2? ( app-crypt/argon2:= )
+	curl? ( net-misc/curl )
+	gcrypt? (
+		dev-libs/libgcrypt:0=
+		dev-libs/libgpg-error
+	)
+	gpg? ( app-crypt/gpgme:= )
+	lz4? ( app-arch/lz4:= )
+	lzo? ( dev-libs/lzo:2 )
+	nls? ( virtual/libintl )
+	rsync? ( net-libs/librsync:= )
+	threads? ( dev-libs/libthreadar )
+	xattr? ( sys-apps/attr )
+"
+
+DEPEND="${RDEPEND}"
+
+BDEPEND="
+	doc? ( app-doc/doxygen )
+	nls? ( sys-devel/gettext )
+"
+
+src_configure() {
+	# configure.ac is totally funked up regarding the AC_ARG_ENABLE
+	# logic.
+	# For example "--enable-dar-static" causes configure to DISABLE
+	# static builds of dar.
+	# Do _not_ use $(use_enable) until you have verified that the
+	# logic has been fixed by upstream.
+	local myconf=(
+		--disable-dar-static
+		--disable-python-binding
+		--disable-upx
+		$(usev !argon2 --disable-libargon2-linking)
+		$(usev !curl --disable-libcurl-linking)
+		$(usev dar32 --enable-mode=32)
+		$(usev dar64 --enable-mode=64)
+		$(usev !doc --disable-build-html)
+		$(usev !gcrypt --disable-libgcrypt-linking)
+		$(usev !gpg --disable-gpgme-linking)
+		$(usev !lz4 --disable-liblz4-linking)
+		$(usev !lzo --disable-liblzo2-linking)
+		$(usev !nls --disable-nls)
+		$(usev !rsync --disable-librsync-linking)
+		$(usev !threads --disable-threadar)
+		$(usev !xattr --disable-ea-support)
+	)
+
+	# Bug 103741
+	filter-flags -fomit-frame-pointer
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	emake DESTDIR="${D}" pkgdatadir="${EPREFIX}"/usr/share/doc/${PF}/html install
+
+	einstalldocs
+
+	find "${ED}" -name "*.la" -delete || die
+
+	# Bug 729150
+	rm "${ED}/usr/share/doc/${PF}/html/samples/MyBackup.sh.tar.gz" || die
+}