app-forensics/magicrescue: update EAPI 7 -> 8; use gbdm unconditionally (not bdb)

|| ( ... ) deps don't work correctly for libraries anyway and we're
working to remove bdb as much as possible.

Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 40 insertions, 0 deletions

diff --git a/app-forensics/magicrescue/magicrescue-1.1.10-r1.ebuild b/app-forensics/magicrescue/magicrescue-1.1.10-r1.ebuild
new file mode 100644
index 000000000000..7c873a505675
--- /dev/null
+++ b/app-forensics/magicrescue/magicrescue-1.1.10-r1.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="Find deleted files in block devices"
+HOMEPAGE="https://github.com/jbj/magicrescue"
+SRC_URI="https://github.com/jbj/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+DEPEND="sys-libs/gdbm"
+RDEPEND="${DEPEND}
+	!net-mail/safecat"
+# File collision with net-mail/safecat, #702004
+
+PATCHES=(
+	"${FILESDIR}/${P}-ldflags.patch"
+	"${FILESDIR}/${P}-remove_toolsdir.patch"
+)
+
+src_prepare() {
+	default
+
+	sed -i -e "\
+			s:\$(INSTALLDIR)/share/magicrescue/recipes:\$(INSTALLDIR)/share/doc/${PF}/recipes:;\
+			s:\$(INSTALLDIR)/man/man1:\$(INSTALLDIR)/share/man/man1:;\
+			s:\$(INSTALLDIR)/share/magicrescue/tools:\$(INSTALLDIR)/bin:" Makefile.in || die "could not mangle Makefile.in"
+}
+
+src_configure() {
+	tc-export CC
+
+	# Not autotools, just looks like it sometimes
+	./configure --prefix=/usr || die
+}