games-roguelike/stone-soup: add 0.31.0_pre20231027

Signed-off-by: Erik Mackdanz <stasibear@gentoo.org>

2 files changed, 240 insertions, 0 deletions

diff --git a/games-roguelike/stone-soup/Manifest b/games-roguelike/stone-soup/Manifest
index b80f32953440..981029eacdd5 100644
--- a/games-roguelike/stone-soup/Manifest
+++ b/games-roguelike/stone-soup/Manifest
@@ -13,6 +13,7 @@ DIST stone-soup-0.30.1.tar.gz 21502317 BLAKE2B 5fc39bb83c5d6b96a00d55c4bf18ee0e6
 DIST stone-soup-0.30.png 1351 BLAKE2B cc31abd59701aa6f0fb0bdcd90630ceebf7b3cb8b60f0e2817f8800c5bc4b3a5b9fef63c90a97b6248f306e7e3da0df3863a2195b8771863344d2443e7956d59 SHA512 4695204c8b936f7aac1ba15b02a6115a955fb2c56aa9a0b968ff007bc9a1a59b608110d60cce5625a9b92cd2c869bbea7e15433a53c1a338622809477a5846bc
 DIST stone-soup-0.30.svg 68546 BLAKE2B 7c66286c9e8a3516e8483b3edb628a59fce29d8d248c3fd5b06e308782bbc651814f21ec958b30c36074a2576ced4bb10f291b5236da6f6e865ce1d7cefdf96d SHA512 dca555271faf704eb8ecdf5ee8a763df42cdeba94e9c163608c438cfc73c6fbf53416547050cad57f477ade191842e701785b65b7a9f18e27ceab05df8f2f75f
 DIST stone-soup-0.31.0_pre20230712.tar.gz 21654476 BLAKE2B c58e59eee09996d109aeb2ef21334497b18b665cfef42c77857446bf8108fe0e50064a29e662eb7c513026fba4f9f1b8ebe2122d5fc317223f61037ac31bee68 SHA512 bad8ba6a4479ed34f1a5b081062db11eb73f8a6cd7637a44c8c7da7013b0a0b943ef921345f5071be245eb7a575bffaef1c04973d634b6c5092a09211126f46a
+DIST stone-soup-0.31.0_pre20231027.tar.gz 22093957 BLAKE2B 7f434b3430f2b4c99abbb52fd245349caaf3864fc992263482144e1bb3c12a9b58be8b918d21c829e8c188116900dfbac082f5e1c490faf4f4a27e1d04998fd5 SHA512 76f957e5cbd580969aa8c1aa09c47604bb0eee85ea3e7895d3e311567a0ec5ece51b3816b143233e2be9a434baf7ad5dd86d815d06bd6ec6e9aac0df5d3d8ac5
 DIST stone-soup-0.31.png 1351 BLAKE2B cc31abd59701aa6f0fb0bdcd90630ceebf7b3cb8b60f0e2817f8800c5bc4b3a5b9fef63c90a97b6248f306e7e3da0df3863a2195b8771863344d2443e7956d59 SHA512 4695204c8b936f7aac1ba15b02a6115a955fb2c56aa9a0b968ff007bc9a1a59b608110d60cce5625a9b92cd2c869bbea7e15433a53c1a338622809477a5846bc
 DIST stone-soup-0.31.svg 68546 BLAKE2B 7c66286c9e8a3516e8483b3edb628a59fce29d8d248c3fd5b06e308782bbc651814f21ec958b30c36074a2576ced4bb10f291b5236da6f6e865ce1d7cefdf96d SHA512 dca555271faf704eb8ecdf5ee8a763df42cdeba94e9c163608c438cfc73c6fbf53416547050cad57f477ade191842e701785b65b7a9f18e27ceab05df8f2f75f
 DIST stone_soup-0.25.1.zip 95477710 BLAKE2B 0b38a6c7cb7c4c87acccb861b5aae665cd2b6b532f6e86d4a9fa594e0d363b86b4af1ea47275f7fd026ea69d85215be8cdf46258bd620e738b4850e5eceed006 SHA512 fa7e8be582c5c6615531884ade4c113542c06c164b6912095c1adf2f16a31cb2ecce057d74132b11b1b1c256a77433037948d4e54819739b7e222cc896cd5220
diff --git a/games-roguelike/stone-soup/stone-soup-0.31.0_pre20231027.ebuild b/games-roguelike/stone-soup/stone-soup-0.31.0_pre20231027.ebuild
new file mode 100644
index 000000000000..3a5d25dadbbf
--- /dev/null
+++ b/games-roguelike/stone-soup/stone-soup-0.31.0_pre20231027.ebuild
@@ -0,0 +1,239 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# There are many slots for this package because people in the community
+# like to play old versions.  Every release includes content changes
+# where species/spells/monsters are added or removed.  The public
+# servers (e.g. http://crawl.akrasiac.org:8080) usually support playing
+# versions back to 0.11.
+
+# It's not necessary for Gentoo to support these old version but it's
+# something nice that our distro can offer that others don't.  If the
+# maintenance burden becomes excessive than we can revisit that
+# position.
+
+EAPI=8
+
+LUA_COMPAT=( lua5-1 )
+LUA_REQ_USE="deprecated"
+PYTHON_COMPAT=( python3_{10,11,12} )
+VIRTUALX_REQUIRED="manual"
+inherit desktop python-any-r1 lua-single xdg-utils toolchain-funcs
+
+DESCRIPTION="Role-playing roguelike game of exploration and treasure-hunting in dungeons"
+HOMEPAGE="https://crawl.develz.org"
+SLOT="0.31"
+
+# Leave empty string if not a _pre release
+COMMITSHA="75a2e9a4b400dc4ea8016b403626a028986a60ef"
+if [ -z "${COMMITSHA}" ]; then
+	# This is a tagged release
+	# Note the archive URI and file layout changed upstream between 0.29.0 and 0.29.1
+	SRC_URI="
+		https://github.com/crawl/crawl/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz
+	"
+	MY_P="crawl-${PV}/crawl-ref"
+else
+	# This is a _pre release
+	SRC_URI="
+		https://github.com/crawl/crawl/archive/${COMMITSHA}.tar.gz -> ${P}.tar.gz
+	"
+	MY_P="crawl-${COMMITSHA}/crawl-ref"
+fi
+SRC_URI="
+	${SRC_URI}
+	https://dev.gentoo.org/~stasibear/distfiles/${PN}.png -> ${PN}-${SLOT}.png
+	https://dev.gentoo.org/~stasibear/distfiles/${PN}.svg -> ${PN}-${SLOT}.svg
+"
+
+# 3-clause BSD: mt19937ar.cc, MSVC/stdint.h
+# 2-clause BSD: all contributions by Steve Noonan and Jesse Luehrs
+# Public Domain|CC0: most of tiles
+# MIT: json.cc/json.h, some .js files in webserver/static/scripts/contrib/
+LICENSE="GPL-2 BSD BSD-2 public-domain CC0-1.0 MIT"
+KEYWORDS="~amd64 ~x86"
+IUSE="advpng debug ncurses sound test +tiles"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+S=${WORKDIR}/${MY_P}/source
+RDEPEND="
+	${LUA_DEPS}
+	dev-db/sqlite:3
+	sys-libs/zlib
+	!ncurses? ( !tiles? ( sys-libs/ncurses:0 ) )
+	ncurses? ( sys-libs/ncurses:0 )
+	tiles? (
+		media-fonts/dejavu
+		media-libs/freetype:2
+		media-libs/libpng:0
+		sound? (
+			   media-libs/libsdl2[X,opengl,sound,video]
+			   media-libs/sdl2-mixer
+		)
+		!sound? ( media-libs/libsdl2[X,opengl,video] )
+		media-libs/sdl2-image[png]
+		virtual/glu
+		virtual/opengl
+	)"
+DEPEND="${RDEPEND}
+	test? ( <dev-cpp/catch-3.0.0:0 )
+	tiles? (
+		sys-libs/ncurses:0
+	)
+	"
+BDEPEND="
+	app-arch/unzip
+	dev-lang/perl
+	${PYTHON_DEPS}
+	$(python_gen_any_dep 'dev-python/pyyaml[${PYTHON_USEDEP}]')
+	sys-devel/flex
+	tiles? (
+		advpng? (
+			app-arch/advancecomp
+		)
+		!advpng? (
+			media-gfx/pngcrush
+		)
+	)
+	virtual/pkgconfig
+	app-alternatives/yacc
+	"
+
+PATCHES=(
+	"${FILESDIR}"/make-v3.patch
+	"${FILESDIR}"/rltiles-make.patch
+	"${FILESDIR}"/avoid-musl-execinfo.patch
+)
+
+python_check_deps() {
+	python_has_version "dev-python/pyyaml[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+
+	if use !ncurses && use !tiles ; then
+		ewarn "Neither ncurses nor tiles frontend"
+		ewarn "selected, choosing ncurses only."
+		ewarn "Note that you can also enable both."
+	fi
+
+	if use sound && use !tiles ; then
+		ewarn "Sound support is only available with tiles."
+	fi
+}
+
+src_prepare() {
+	default
+	python_fix_shebang "${S}/util/species-gen.py"
+
+	if use advpng; then
+		eapply "${FILESDIR}/make-advpng.patch"
+	fi
+
+	sed -i -e "s/GAME = crawl$/GAME = crawl-${SLOT}/" "${S}/Makefile" \
+		|| die "Couldn't append slot to executable name"
+
+	# File required for a _pre build
+	if ! [ -f "${S}/util/release_ver" ]; then
+		echo "${SLOT}" >"${S}/util/release_ver" || die "Couldn't write release_ver"
+	fi
+
+	# Replace bundled catch2 package with system implementation
+	# https://bugs.gentoo.org/829950
+	if use test; then
+		cp /usr/include/catch2/catch.hpp "${S}/catch2-tests" || die "Couldn't substitute system catch2"
+	fi
+}
+
+src_compile() {
+
+	# Insurance that we're not using bundled lib sources
+	rm -rf contrib || die "Couldn't delete contrib directory"
+
+	myemakeargs=(
+		$(usex debug "FULLDEBUG=y DEBUG=y" "")
+		BUILD_LUA=
+		AR="$(tc-getAR)"
+		CFOPTIMIZE=''
+		# -DLUA_COMPAT_OPENLIB=1 is required to enable the
+		# deprecated (in 5.1) luaL_openlib API (#869671)
+		CFOTHERS="${CXXFLAGS} -DLUA_COMPAT_OPENLIB=1"
+		CONTRIBS=
+		DATADIR="/usr/share/${PN}-${SLOT}"
+		FORCE_CC="$(tc-getCC)"
+		FORCE_CXX="$(tc-getCXX)"
+		LDFLAGS="${LDFLAGS}"
+		MAKEOPTS="${MAKEOPTS}"
+		PKGCONFIG="$(tc-getPKG_CONFIG)"
+		RANLIB="$(tc-getRANLIB)"
+		SAVEDIR="~/.crawl-${SLOT}"
+		SOUND=$(usex sound "y" "")
+		STRIP=touch
+		USE_LUAJIT=
+		V=1
+		prefix="/usr"
+	)
+
+	if use ncurses || (use !ncurses && use !tiles) ; then
+		emake "${myemakeargs[@]}"
+		# move it in case we build both variants
+		use tiles && { mv "crawl-${SLOT}" "${WORKDIR}"/crawl-ncurses-${SLOT} || die ;}
+	fi
+
+	if use tiles ; then
+		emake "${myemakeargs[@]}" clean
+		emake "${myemakeargs[@]}" "TILES=y"
+	fi
+}
+
+src_test() {
+	emake "${myemakeargs[@]}" \
+		  $(usex tiles "TILES=y" "") \
+		  catch2-tests
+}
+
+src_install() {
+	emake "${myemakeargs[@]}" \
+		  $(usex tiles "TILES=y" "") \
+		  DESTDIR="${D}" \
+		  prefix_fp="" \
+		  bin_prefix="${D}/usr/bin" \
+		  install
+
+	[[ -e "${WORKDIR}/crawl-ncurses-${SLOT}" ]] && dobin "${WORKDIR}/crawl-ncurses-${SLOT}"
+
+	# don't relocate docs, needed at runtime
+	rm -rf "${D}/usr/share/${PN}-${SLOT}"/docs/license
+
+	mv "${WORKDIR}/${MY_P}"/docs/crawl.6 "${WORKDIR}/${MY_P}/docs/crawl-${SLOT}.6" \
+	   || die "Couldn't append slot to man page name"
+	doman "${WORKDIR}/${MY_P}/docs/crawl-${SLOT}.6"
+
+	# icons and menu for graphical build
+	if use tiles ; then
+		doicon -s 48 "${DISTDIR}"/${PN}-${SLOT}.png
+		doicon -s scalable "${DISTDIR}"/${PN}-${SLOT}.svg
+		make_desktop_entry "crawl-${SLOT}" "crawl-${SLOT}" "crawl-${SLOT}"
+	fi
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+
+	elog "crawl is a slotted install that supports having"
+	elog "multiple versions installed.  The binary has the"
+	elog "slot appended, e.g. 'crawl-"${SLOT}"'."
+
+	if use tiles && use ncurses ; then
+		elog
+		elog "Since you have enabled both tiles and ncurses frontends"
+		elog "the ncurses binary is called 'crawl-ncurses-"${SLOT}"' and the"
+		elog "tiles binary is called 'crawl-"${SLOT}"'."
+	fi
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}