gnome-extra/gnome-software: version bump 3.20.5 → 3.22.1

Package-Manager: portage-2.3.1

2 files changed, 82 insertions, 0 deletions

diff --git a/gnome-extra/gnome-software/Manifest b/gnome-extra/gnome-software/Manifest
index 1873d32fa84e..95f7c358e106 100644
--- a/gnome-extra/gnome-software/Manifest
+++ b/gnome-extra/gnome-software/Manifest
@@ -1,2 +1,3 @@
 DIST gnome-software-3.20.4.tar.xz 3513716 SHA256 d6a2794348e2c543218e3efb01105a7e6d51e93ad3055a2482e3104ca75345f2 SHA512 ea4536acc954f3d5d5d834323580041fe03099a6733a64f0c6a60f40028e0f054a4f9161b4fdd0956be8aa5ba25eed53748b28fff8d1c05b03ff314af6380fdf WHIRLPOOL e62085795f5eb84d0b94e140f83c7c759ea0bf7b2026890b19bd40cebbff3c53395ed820002657893846cccd505cfe0db0ca2f148ef3204c96d40059c0f2f357
 DIST gnome-software-3.20.5.tar.xz 3533740 SHA256 3880efea8edef3c34471cd9cba9ec8de1c06ef080d4dac723433df710f74b767 SHA512 36a827ef459e96b44c32bee63dacf3ccd0acaaead79a21337a3ab54df60d8eec32afd14db7f0cb0f53f179a38fa628f75935898c8d5c1b8355404ab485b0cdcf WHIRLPOOL f5ddc104aeaf08474c7cb1bb41d25ac975a4fe81fc422d62f65eb6ad22788e125a48c377c939e3b07979a252afd48db6432b1779d1c8ad676e73874e6f2d85ed
+DIST gnome-software-3.22.1.tar.xz 3857348 SHA256 427e6aa43eddd49d2937bb025691b52c41b686b7b00f1961d202527ced371012 SHA512 d4da3decd0c85e2cf3332baaa92886112028ae3063b8bbf8315995d01ddb6b9a7e3841301cf4445a0b6cef9287dc554f8469d9e2e5f779c3105d686d5677f5ce WHIRLPOOL d42a8f836b41de3189ccc90252ec97a46b4cfae4035c04518c0d1f7a6e4cbd5d0281e03b178dac0c14e92e99729f6c31deb231c1b1e447b71714359debd62f41
diff --git a/gnome-extra/gnome-software/gnome-software-3.22.1.ebuild b/gnome-extra/gnome-software/gnome-software-3.22.1.ebuild
new file mode 100644
index 000000000000..be12046eaa08
--- /dev/null
+++ b/gnome-extra/gnome-software/gnome-software-3.22.1.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+
+inherit gnome2 python-any-r1 virtualx
+
+DESCRIPTION="Gnome install & update software"
+HOMEPAGE="http://wiki.gnome.org/Apps/Software"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gnome spell test udev"
+
+RDEPEND="
+	>=app-admin/packagekit-base-1.1.0
+	app-crypt/libsecret
+	dev-db/sqlite:3
+	>=dev-libs/appstream-glib-0.6.1:0
+	>=dev-libs/glib-2.46:2
+	>=dev-libs/json-glib-1.1.1
+	>=gnome-base/gsettings-desktop-schemas-3.11.5
+	>=net-libs/libsoup-2.51.92:2.4
+	sys-auth/polkit
+	>=x11-libs/gdk-pixbuf-2.31.5
+	>=x11-libs/gtk+-3.20:3
+	gnome? ( >=gnome-base/gnome-desktop-3.17.92:3= )
+	spell? ( app-text/gtkspell:3 )
+	udev? ( virtual/libgudev )
+"
+DEPEND="${RDEPEND}
+	app-text/docbook-xml-dtd:4.2
+	dev-libs/libxslt
+	>=dev-util/intltool-0.35
+	virtual/pkgconfig
+	test? (
+		${PYTHON_DEPS}
+		$(python_gen_any_dep 'dev-util/dogtail[${PYTHON_USEDEP}]') )
+"
+# test? ( dev-util/valgrind )
+
+python_check_deps() {
+	use test && has_version "dev-util/dogtail[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	# valgrind fails with SIGTRAP
+	sed -e 's/TESTS = .*/TESTS =/' \
+		-i "${S}"/src/Makefile.{am,in} || die
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# FIXME: investigate limba and firmware update support
+	gnome2_src_configure \
+		--enable-man \
+		--enable-packagekit \
+		--enable-polkit \
+		--disable-firmware \
+		--disable-limba \
+		--disable-ostree \
+		--disable-rpm \
+		--disable-steam \
+		--disable-xdg-app \
+		$(use_enable spell gtkspell) \
+		$(use_enable test dogtail) \
+		$(use_enable test tests) \
+		$(use_enable udev gudev)
+}
+
+src_test() {
+	virtx emake check TESTS_ENVIRONMENT="dbus-run-session"
+}