1 files changed, 51 insertions, 0 deletions
diff --git a/dev-libs/libnsfb/libnsfb-0.2.1-r1.ebuild b/dev-libs/libnsfb/libnsfb-0.2.1-r1.ebuild
new file mode 100644
index 000000000000..354ba28b0bb9
--- /dev/null
+++ b/dev-libs/libnsfb/libnsfb-0.2.1-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit netsurf
+
+DESCRIPTION="framebuffer abstraction library, written in C"
+HOMEPAGE="http://www.netsurf-browser.org/projects/libnsfb/"
+SRC_URI="https://download.netsurf-browser.org/libs/releases/${P}-src.tar.gz"
+
+LICENSE="MIT"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64"
+IUSE="sdl test vnc wayland X"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="sdl? ( >=media-libs/libsdl-1.2.15-r4 )
+	vnc? ( >=net-libs/libvncserver-0.9.9-r2 )
+	wayland? ( >=dev-libs/wayland-1.0.6 )
+	X? (
+		>=x11-libs/libxcb-1.9.1
+		>=x11-libs/xcb-util-0.3.9-r1
+		>=x11-libs/xcb-util-image-0.3.9-r1
+		>=x11-libs/xcb-util-keysyms-0.3.9-r1
+	)"
+BDEPEND="
+	dev-util/netsurf-buildsystem"
+
+PATCHES=( "${FILESDIR}"/${PN}-0.1.0-autodetect.patch )
+
+DOCS=( usage )
+
+_emake() {
+	netsurf_define_makeconf
+	emake "${NETSURF_MAKECONF[@]}" COMPONENT_TYPE=lib-shared \
+		WITH_VNC=$(usex vnc) \
+		WITH_SDL=$(usex sdl) \
+		WITH_XCB=$(usex X) \
+		WITH_WLD=$(usex wayland) \
+		$@
+}
+
+src_compile() {
+	_emake
+}
+
+src_install() {
+	_emake DESTDIR="${D}" install
+}