2 files changed, 60 insertions, 0 deletions
diff --git a/gnome-extra/gnome-clocks/Manifest b/gnome-extra/gnome-clocks/Manifest
index c856fb4e1659..ae0d88d8362b 100644
--- a/gnome-extra/gnome-clocks/Manifest
+++ b/gnome-extra/gnome-clocks/Manifest
@@ -1 +1,2 @@
 DIST gnome-clocks-44.0.tar.xz 368556 BLAKE2B 8cf6bfd1dfbea769b71d74bcb864ccea5393410a90b3d83d6e053afef971c71ac7d35cfdc7b200695c3ffbb2c049baa19c5af0f4042efa7563012e5b333f5c82 SHA512 f262a18d13e5cb373760b02aa4dd79d7e6843aa400813d0c108bee0dfc084fb3d734e01cf1ffeadb34eb0f3e4db29d85d6817a98afa7864e997d7e2c5425d1bd
+DIST gnome-clocks-45.0.tar.xz 456820 BLAKE2B c88472cec03246192dbc765cb7896d2771c0cae49249687a06e8382289339cd24a7fe65266d0d2a8834d0956a043c14c4b60c646cab4183e9530ea74915d95d8 SHA512 c030947bbba03ed3815a2ed62356a8aa54ec130bf8a7fe17e028af3b27fa8c6f02d365267e466867fea6e4daa36907193e0fb07c04ce0c390f20e01d4a6e716f
diff --git a/gnome-extra/gnome-clocks/gnome-clocks-45.0.ebuild b/gnome-extra/gnome-clocks/gnome-clocks-45.0.ebuild
new file mode 100644
index 000000000000..78ca18f5bcc8
--- /dev/null
+++ b/gnome-extra/gnome-clocks/gnome-clocks-45.0.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson vala xdg
+
+DESCRIPTION="Clocks application for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Clocks https://gitlab.gnome.org/GNOME/gnome-clocks"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-libs/glib-2.72:2
+	>=gui-libs/gtk-4.5:4
+	>=dev-libs/libgweather-4.2.0:4=
+	gnome-base/gnome-desktop:4=
+	>=sci-geosciences/geocode-glib-1:2
+	>=app-misc/geoclue-2.4:2.0
+	>=gui-libs/libadwaita-1.4_alpha:1
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-libs/libxml2:2
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	$(vala_depend)
+	>=dev-libs/libgweather-4.2.0:4[vala]
+	gui-libs/libadwaita:1[vala]
+"
+
+DOCS=( AUTHORS.md CONTRIBUTING.md README.md )
+
+src_prepare() {
+	default
+	vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dprofile=default
+		-Ddocs=false
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}