From 78812ee4feafba07e463e940b72255c508d1dfd8 Mon Sep 17 00:00:00 2001
From: Alfredo Tupone <tupone@gentoo.org>
Date: Mon, 16 May 2022 15:13:49 +0200
Subject: dev-libs/FP16: add PeachPy depend

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Alfredo Tupone <tupone@gentoo.org>
---
 dev-libs/FP16/FP16-2021.03.20-r1.ebuild | 54 +++++++++++++++++++++++++++++++++
 dev-libs/FP16/FP16-2021.03.20.ebuild    | 35 ---------------------
 2 files changed, 54 insertions(+), 35 deletions(-)
 create mode 100644 dev-libs/FP16/FP16-2021.03.20-r1.ebuild
 delete mode 100644 dev-libs/FP16/FP16-2021.03.20.ebuild

diff --git a/dev-libs/FP16/FP16-2021.03.20-r1.ebuild b/dev-libs/FP16/FP16-2021.03.20-r1.ebuild
new file mode 100644
index 000000000000..4fb39fced810
--- /dev/null
+++ b/dev-libs/FP16/FP16-2021.03.20-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8,9,10,11} )
+inherit python-r1 cmake
+
+CommitId=0a92994d729ff76a58f692d3028ca1b64b145d91
+
+DESCRIPTION="conversion to/from half-precision floating point formats"
+HOMEPAGE="https://github.com/Maratyszcza/FP16/"
+SRC_URI="https://github.com/Maratyszcza/${PN}/archive/${CommitId}.tar.gz
+	-> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="dev-libs/psimd"
+RDEPEND="${DEPEND} ${PYTHON_DEPS}"
+BDEPEND="test? ( dev-cpp/gtest )"
+RESTRICT="!test? ( test )"
+
+S="${WORKDIR}"/${PN}-${CommitId}
+
+PATCHES=(
+	"${FILESDIR}"/${P}-gentoo.patch
+)
+
+src_prepare() {
+	cmake_src_prepare
+	mkdir -p module/fp16 || die
+	cp include/fp16/*py module/fp16 || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DFP16_BUILD_BENCHMARKS=OFF
+		-DFP16_BUILD_TESTS=$(usex test ON OFF)
+	)
+	cmake_src_configure
+}
+
+python_install() {
+	python_domodule module/fp16
+}
+
+src_install() {
+	cmake_src_install
+	rm "${D}"/usr/include/fp16/*.py || die
+	python_foreach_impl python_install
+}
diff --git a/dev-libs/FP16/FP16-2021.03.20.ebuild b/dev-libs/FP16/FP16-2021.03.20.ebuild
deleted file mode 100644
index 160c3c91f429..000000000000
--- a/dev-libs/FP16/FP16-2021.03.20.ebuild
+++ /dev/null
@@ -1,35 +0,0 @@
-# Copyright 2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-inherit cmake
-
-CommitId=0a92994d729ff76a58f692d3028ca1b64b145d91
-DESCRIPTION="conversion to/from half-precision floating point formats"
-HOMEPAGE="https://github.com/Maratyszcza/FP16/"
-SRC_URI="https://github.com/Maratyszcza/${PN}/archive/${CommitId}.tar.gz
-	-> ${P}.tar.gz"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64"
-IUSE="test"
-
-DEPEND="dev-libs/psimd"
-RDEPEND="${DEPEND}"
-BDEPEND="test? ( dev-cpp/gtest )"
-RESTRICT="!test? ( test )"
-
-S="${WORKDIR}"/${PN}-${CommitId}
-
-PATCHES=(
-	"${FILESDIR}"/${P}-gentoo.patch
-)
-
-src_configure() {
-	local mycmakeargs=(
-		-DFP16_BUILD_BENCHMARKS=OFF
-		-DFP16_BUILD_TESTS=$(usex test ON OFF)
-	)
-	cmake_src_configure
-}
-- 
cgit v1.2.3-65-gdbad