From 42896c6585ba86ea1fe5049dc6da526c888eb449 Mon Sep 17 00:00:00 2001
From: Viorel Munteanu <ceamac@gentoo.org>
Date: Tue, 7 Nov 2023 07:15:35 +0200
Subject: app-misc/fastfetch: drop 2.2.1

Signed-off-by: Viorel Munteanu <ceamac@gentoo.org>
---
 app-misc/fastfetch/Manifest               |   1 -
 app-misc/fastfetch/fastfetch-2.2.1.ebuild | 108 ------------------------------
 2 files changed, 109 deletions(-)
 delete mode 100644 app-misc/fastfetch/fastfetch-2.2.1.ebuild

(limited to 'app-misc')

diff --git a/app-misc/fastfetch/Manifest b/app-misc/fastfetch/Manifest
index fab2be193a33..a783dd24ee3c 100644
--- a/app-misc/fastfetch/Manifest
+++ b/app-misc/fastfetch/Manifest
@@ -1,3 +1,2 @@
 DIST fastfetch-1.12.2.tar.gz 538194 BLAKE2B bc6badbc7f690dacbe1408479286a0d42ec687526f776ff4d2ec7b0eb767032e5781cbbe37778f4dc03a5d386979a9ae2aab84c466be997b82d9a9a6c81ea78f SHA512 a82a7c7ae365335c20d659a82215cf320c4c6b07ff127c4dad322a0a01f7ec57e34d229f4953108daadcd0d243c84f8504a3b4367df5e255e5a06e685fd6739a
-DIST fastfetch-2.2.1.tar.gz 899131 BLAKE2B bc40bb876b11a41f211f265c6b760ec2905c2d10240c67f514da4f70935f40ff1759ac52bbf5183e96537ab8a963d1df5bf9ebc527927f25d1a453243495ccef SHA512 ba9eb36dd11a5346ed0ad452aecaf79e556fd91e91c6fa6e19c8b04c401f4ff383687c8afe5b2cba2281b086859246e16e2ac231f46893217d4f1241b6f4a439
 DIST fastfetch-2.2.2.tar.gz 900528 BLAKE2B 435e42748d24c7dc20bc5081fb45b55d71391a60f830d3dd18b63c604f09c4e8c66ce4a58a1e80e9e78cf7886805fbddc3e9e46a85d6f93cf219b1cbf9789c11 SHA512 f4ba2b9ffd68fe76043089595445d3f2227152292dfeaf9ecaa45dd18def0c1dd3a9e113aea92bd2361699bdef7a44e1bdc45486b2f3f123428c500e747a0bb5
diff --git a/app-misc/fastfetch/fastfetch-2.2.1.ebuild b/app-misc/fastfetch/fastfetch-2.2.1.ebuild
deleted file mode 100644
index f3c91c217ba1..000000000000
--- a/app-misc/fastfetch/fastfetch-2.2.1.ebuild
+++ /dev/null
@@ -1,108 +0,0 @@
-# Copyright 2022-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit cmake flag-o-matic
-
-DESCRIPTION="Fast neofetch-like system information tool"
-HOMEPAGE="https://github.com/fastfetch-cli/fastfetch"
-if [[ ${PV} == *9999 ]]; then
-	inherit git-r3
-	EGIT_REPO_URI="https://github.com/fastfetch-cli/fastfetch.git"
-	[[ ${PV} == *0.1.9999 ]] && EGIT_BRANCH=master
-	[[ ${PV} == *0.2.9999 ]] && EGIT_BRANCH=dev
-	[[ "${EGIT_BRANCH}" == "" ]] && die "Please set a git branch"
-else
-	SRC_URI="https://github.com/fastfetch-cli/fastfetch/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~riscv ~x86"
-fi
-
-LICENSE="MIT"
-SLOT="0"
-IUSE="X chafa dbus ddcutil gnome imagemagick networkmanager opencl opengl osmesa pci pulseaudio sqlite test vulkan wayland xcb xfce xrandr"
-RESTRICT="!test? ( test )"
-
-# note - qa-vdb will always report errors because fastfetch loads the libs dynamically
-# make sure to crank yyjson minimum version to match bundled version
-RDEPEND="
-	>=dev-libs/yyjson-0.8.0:=
-	sys-libs/zlib
-	X? ( x11-libs/libX11 )
-	chafa? ( media-gfx/chafa )
-	dbus? ( sys-apps/dbus )
-	ddcutil? ( app-misc/ddcutil:= )
-	gnome? (
-		dev-libs/glib
-		gnome-base/dconf
-	)
-	imagemagick? ( media-gfx/imagemagick:= )
-	networkmanager? ( net-misc/networkmanager )
-	opencl? ( virtual/opencl )
-	opengl? ( media-libs/libglvnd[X] )
-	osmesa? ( media-libs/mesa[osmesa] )
-	pci? ( sys-apps/pciutils )
-	pulseaudio? ( media-libs/libpulse )
-	sqlite? ( dev-db/sqlite:3 )
-	vulkan? ( media-libs/vulkan-loader )
-	wayland? ( dev-libs/wayland )
-	xcb? ( x11-libs/libxcb )
-	xfce? ( xfce-base/xfconf )
-	xrandr? ( x11-libs/libXrandr )
-"
-DEPEND="${RDEPEND}"
-BDEPEND="virtual/pkgconfig"
-
-REQUIRED_USE="
-	xrandr? ( X )
-	chafa? ( imagemagick )
-"
-
-src_configure() {
-	local fastfetch_enable_imagemagick7=no
-	local fastfetch_enable_imagemagick6=no
-	if use imagemagick; then
-		fastfetch_enable_imagemagick7=$(has_version '>=media-gfx/imagemagick-7.0.0' && echo yes || echo no)
-		fastfetch_enable_imagemagick6=$(has_version '<media-gfx/imagemagick-7.0.0' && echo yes || echo no)
-	fi
-
-	local mycmakeargs=(
-		-DENABLE_RPM=no
-		-DENABLE_ZLIB=yes
-		-DENABLE_SYSTEM_YYJSON=yes
-
-		-DENABLE_CHAFA=$(usex chafa)
-		-DENABLE_DBUS=$(usex dbus)
-		-DENABLE_DDCUTIL=$(usex ddcutil)
-		-DENABLE_DCONF=$(usex gnome)
-		-DENABLE_EGL=$(usex opengl)
-		-DENABLE_GIO=$(usex gnome)
-		-DENABLE_GLX=$(usex opengl)
-		-DENABLE_IMAGEMAGICK6=${fastfetch_enable_imagemagick6}
-		-DENABLE_IMAGEMAGICK7=${fastfetch_enable_imagemagick7}
-		-DENABLE_LIBNM=$(usex networkmanager)
-		-DENABLE_LIBPCI=$(usex pci)
-		-DENABLE_OPENCL=$(usex opencl)
-		-DENABLE_OSMESA=$(usex osmesa)
-		-DENABLE_PULSE=$(usex pulseaudio)
-		-DENABLE_SQLITE3=$(usex sqlite)
-		-DENABLE_VULKAN=$(usex vulkan)
-		-DENABLE_WAYLAND=$(usex wayland)
-		-DENABLE_X11=$(usex X)
-		-DENABLE_XCB=$(usex xcb)
-		-DENABLE_XCB_RANDR=$(usex xcb)
-		-DENABLE_XFCONF=$(usex xfce)
-		-DENABLE_XRANDR=$(usex xrandr)
-		-DBUILD_TESTS=$(usex test)
-	)
-
-	append-cppflags -DNDEBUG
-
-	cmake_src_configure
-}
-
-src_install() {
-	cmake_src_install
-
-	rm -r "${ED}"/usr/share/licenses || die
-}
-- 
cgit v1.2.3-65-gdbad