From 71f1fae01a49ffc6699f1b66d553c842d4e713f0 Mon Sep 17 00:00:00 2001
From: Sebastian Pipping <sping@gentoo.org>
Date: Tue, 14 Mar 2017 00:08:12 +0100
Subject: app-misc/workrave: 1.10.16

Package-Manager: Portage-2.3.4, Repoman-2.3.2
---
 app-misc/workrave/Manifest                |   1 +
 app-misc/workrave/workrave-1.10.16.ebuild | 105 ++++++++++++++++++++++++++++++
 2 files changed, 106 insertions(+)
 create mode 100644 app-misc/workrave/workrave-1.10.16.ebuild

(limited to 'app-misc')

diff --git a/app-misc/workrave/Manifest b/app-misc/workrave/Manifest
index af8cecf4d5a4..f270ae408f5f 100644
--- a/app-misc/workrave/Manifest
+++ b/app-misc/workrave/Manifest
@@ -1 +1,2 @@
 DIST workrave-1.10.15.tar.gz 6375380 SHA256 fa05bedbb32baae9d22ef2b1ac25e90bc9f1363ce588b396190b0240559f471c SHA512 e741f5d0748ffaba9c8e69bcbd67f7b371424423ec8cea81d082462e8c33751c3e322301ae0749037668dc53cab28b19ec2b162f98eb7afbbd5ab85bae33cf7e WHIRLPOOL 02c9f25f06ae0753f7edc418ade789c82bf39736b975e755265a86b2677842098efc966530cf9063401e2e63d9f1670e4fd4ba5d9b635d05faa5cc71b9146afa
+DIST workrave-1.10.16.tar.gz 6375438 SHA256 4368306db0d06e76a3a90fc8e81b3648c1218259833b01cdc6899b1e98e5895c SHA512 f768c46a5b7dfbaca2984fabff92e64d5fd14f3b4e4d018f5a1cf46a87fbf7ec7fbaec9b660e899f7064a93338224d159b75052ed8e532ecaf507d2f249732f2 WHIRLPOOL 2352b05bc1e3fb3787e4c350ab37cb877e9fdce543e4f6e117083f46e79af673b9ae3c21e3e625ed9e1b11c1e5e4072adeff1b6b059b7cd1c6c01bc8ce3a04ac
diff --git a/app-misc/workrave/workrave-1.10.16.ebuild b/app-misc/workrave/workrave-1.10.16.ebuild
new file mode 100644
index 000000000000..84f703aeceea
--- /dev/null
+++ b/app-misc/workrave/workrave-1.10.16.ebuild
@@ -0,0 +1,105 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+
+inherit autotools gnome2 python-single-r1 versionator vcs-snapshot
+
+DESCRIPTION="Helpful utility to attack Repetitive Strain Injury (RSI)"
+HOMEPAGE="http://www.workrave.org/"
+MY_PV=$(replace_all_version_separators '_')
+SRC_URI="https://github.com/rcaelers/${PN}/archive/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+# dbus support looks to be used only for trying to use panel applets on gnome3!
+IUSE="ayatana doc gnome gstreamer introspection mate nls pulseaudio test xfce"
+REQUIRED_USE="ayatana? ( introspection )"
+
+RDEPEND="
+	>=dev-libs/glib-2.28.0:2
+	>=x11-libs/gtk+-3.0:3[introspection?,X]
+	>=dev-cpp/gtkmm-3.0.0:3.0
+	>=dev-cpp/glibmm-2.28.0:2
+	>=dev-libs/libsigc++-2.2.4.2:2
+	ayatana? (
+		>=dev-libs/libdbusmenu-0.4[gtk3,introspection]
+		>=dev-libs/libindicator-0.4:3 )
+	gnome? ( >=gnome-base/gnome-shell-3.6.2 )
+	gstreamer? (
+		media-libs/gstreamer:1.0[introspection?]
+		media-libs/gst-plugins-base:1.0[introspection?]
+		media-plugins/gst-plugins-meta:1.0 )
+	introspection? ( dev-libs/gobject-introspection:= )
+	mate? ( mate-base/mate-applets )
+	pulseaudio? ( >=media-sound/pulseaudio-0.9.15 )
+	xfce? (
+		>=x11-libs/gtk+-2.6.0:2[introspection?]
+		>=xfce-base/xfce4-panel-4.4 )
+	x11-libs/libXScrnSaver
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXtst
+	x11-libs/libXt
+	x11-libs/libXmu
+"
+#        dbus? (
+#                >=sys-apps/dbus-1.2
+#                dev-libs/dbus-glib )
+
+DEPEND="${RDEPEND}
+	dev-python/cheetah
+	>=dev-util/intltool-0.40.0
+	sys-devel/autoconf-archive
+	x11-proto/xproto
+	x11-proto/inputproto
+	x11-proto/recordproto
+	virtual/pkgconfig
+	doc? (
+		app-text/docbook-sgml-utils
+		app-text/xmlto )
+	nls? ( >=sys-devel/gettext-0.17 )
+"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_unpack() {
+	vcs-snapshot_src_unpack
+}
+
+src_prepare() {
+	# Fix gstreamer slot automagic dependency, bug #563584
+	# http://issues.workrave.org/show_bug.cgi?id=1179
+	eapply "${FILESDIR}"/${PN}-1.10.6-automagic-gstreamer.patch
+
+	eautoreconf
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# gnet ("distribution") is dead for ages and other distributions stopped
+	# relying on it for such time too.
+	gnome2_src_configure \
+		--disable-dbus \
+		--disable-distribution \
+		--enable-exercises \
+		--disable-experimental \
+		--disable-gnome2 \
+		--disable-static \
+		--disable-xml \
+		$(use_enable ayatana indicator) \
+		$(use_enable doc manual) \
+		$(use_enable gnome gnome3) \
+		$(use_enable gstreamer) \
+		$(use_enable introspection) \
+		$(use_enable mate) \
+		$(use_enable nls) \
+		$(use_enable pulseaudio pulse) \
+		$(use_enable test tests) \
+		$(use_enable xfce)
+}
-- 
cgit v1.2.3-65-gdbad