From b05b74e96654aceb155fc19ed2c4200f24e17f39 Mon Sep 17 00:00:00 2001
From: James Le Cuirot <chewi@gentoo.org>
Date: Fri, 9 Dec 2022 23:02:17 +0000
Subject: gui-wm/gamescope: Bump to 3.11.51, drop old 3.11.49

Signed-off-by: James Le Cuirot <chewi@gentoo.org>
---
 gui-wm/gamescope/Manifest                 |  2 +-
 gui-wm/gamescope/gamescope-3.11.49.ebuild | 71 ----------------------------
 gui-wm/gamescope/gamescope-3.11.51.ebuild | 78 +++++++++++++++++++++++++++++++
 3 files changed, 79 insertions(+), 72 deletions(-)
 delete mode 100644 gui-wm/gamescope/gamescope-3.11.49.ebuild
 create mode 100644 gui-wm/gamescope/gamescope-3.11.51.ebuild

(limited to 'gui-wm')

diff --git a/gui-wm/gamescope/Manifest b/gui-wm/gamescope/Manifest
index dc9e1ad00d6a..60bdaefe23ee 100644
--- a/gui-wm/gamescope/Manifest
+++ b/gui-wm/gamescope/Manifest
@@ -1 +1 @@
-DIST gamescope-3.11.49.tar.gz 203449 BLAKE2B ed033e1acddf73326efad69ac62d76ab587bb363262340056d260306062d1b52f29e8d19c6e5637414a28f3866f6755401dcc3d29478858f153503c22a6d9de0 SHA512 16f9a47b1e79c4a7bc7de22fda10df7bd1537daae25f41f4ff45882890e38b9892ff6ac42f9da1ace744ef9d37614b4fbcd7805e9af6b94bc421397324dd3413
+DIST gamescope-3.11.51.tar.gz 209920 BLAKE2B fdccd6659e33a9ae43eaabc5d41cfa6d0a92bda1a283e23f101296713f5094093b7b41135de44abd65ff17c66d70b27baf50685dcd2a47084022fb611e150a5b SHA512 a4ddd96a4fdacd62eee800f6fb331d08fca32c2798d64148529181a0ee8d8af57d5d67bfa28bff8e9cf62047a7572c43b36e2968660ea2984b8e21fa812baf9e
diff --git a/gui-wm/gamescope/gamescope-3.11.49.ebuild b/gui-wm/gamescope/gamescope-3.11.49.ebuild
deleted file mode 100644
index 7d3ecfd59c34..000000000000
--- a/gui-wm/gamescope/gamescope-3.11.49.ebuild
+++ /dev/null
@@ -1,71 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit fcaps meson
-
-MY_PV=$(ver_rs 3 -)
-MY_PV="${MY_PV//_/-}"
-DESCRIPTION="Efficient micro-compositor for running games"
-HOMEPAGE="https://github.com/Plagman/gamescope"
-SRC_URI="https://github.com/Plagman/${PN}/archive/refs/tags/${MY_PV}.tar.gz -> ${P}.tar.gz"
-KEYWORDS="~amd64"
-LICENSE="BSD-2"
-SLOT="0"
-IUSE="pipewire"
-
-RDEPEND="
-	=dev-libs/libliftoff-0.3*
-	>=dev-libs/wayland-1.21
-	>=dev-libs/wayland-protocols-1.17
-	=gui-libs/wlroots-0.15*[X]
-	media-libs/libsdl2[video]
-	media-libs/vulkan-loader
-	sys-apps/hwdata
-	sys-libs/libcap
-	>=x11-libs/libdrm-2.4.109
-	x11-libs/libX11
-	x11-libs/libXcomposite
-	x11-libs/libXdamage
-	x11-libs/libXext
-	x11-libs/libXfixes
-	x11-libs/libxkbcommon
-	x11-libs/libXrender
-	x11-libs/libXres
-	x11-libs/libXtst
-	x11-libs/libXxf86vm
-	pipewire? ( >=media-video/pipewire-0.3:= )
-"
-DEPEND="
-	${RDEPEND}
-	dev-libs/stb
-	dev-util/vulkan-headers
-"
-BDEPEND="
-	dev-util/glslang
-	dev-util/wayland-scanner
-"
-
-S="${WORKDIR}/${PN}-${MY_PV}"
-
-FILECAPS=(
-	cap_sys_nice usr/bin/${PN}
-)
-
-src_prepare() {
-	default
-
-	# Normally uses stb from a git submodule. Upstream does not ship a
-	# pkg-config file so we don't install one. Work around this using symlinks.
-	mkdir subprojects/stb || die
-	ln -snf "${ESYSROOT}"/usr/include/stb/* "${S}"/subprojects/packagefiles/stb/* subprojects/stb/ || die
-}
-
-src_configure() {
-	local emesonargs=(
-		--force-fallback-for=
-		$(meson_feature pipewire)
-	)
-	meson_src_configure
-}
diff --git a/gui-wm/gamescope/gamescope-3.11.51.ebuild b/gui-wm/gamescope/gamescope-3.11.51.ebuild
new file mode 100644
index 000000000000..a8464a5a2e68
--- /dev/null
+++ b/gui-wm/gamescope/gamescope-3.11.51.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit fcaps meson
+
+MY_PV=$(ver_rs 3 -)
+MY_PV="${MY_PV//_/-}"
+DESCRIPTION="Efficient micro-compositor for running games"
+HOMEPAGE="https://github.com/Plagman/gamescope"
+SRC_URI="https://github.com/Plagman/${PN}/archive/refs/tags/${MY_PV}.tar.gz -> ${P}.tar.gz"
+KEYWORDS="~amd64"
+LICENSE="BSD-2"
+SLOT="0"
+IUSE="pipewire"
+
+RDEPEND="
+	=dev-libs/libliftoff-0.3*
+	>=dev-libs/wayland-1.21
+	>=dev-libs/wayland-protocols-1.17
+	=gui-libs/wlroots-0.16*[X]
+	media-libs/libsdl2[video,vulkan]
+	media-libs/vulkan-loader
+	sys-apps/hwdata
+	sys-libs/libcap
+	>=x11-libs/libdrm-2.4.109
+	x11-libs/libX11
+	x11-libs/libxcb
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libxkbcommon
+	x11-libs/libXrender
+	x11-libs/libXres
+	x11-libs/libXtst
+	x11-libs/libXxf86vm
+	pipewire? ( >=media-video/pipewire-0.3:= )
+"
+DEPEND="
+	${RDEPEND}
+	dev-libs/stb
+	dev-util/vulkan-headers
+	media-libs/vkroots
+"
+BDEPEND="
+	dev-util/glslang
+	dev-util/wayland-scanner
+"
+
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+FILECAPS=(
+	cap_sys_nice usr/bin/${PN}
+)
+
+src_prepare() {
+	default
+
+	# Normally uses stb from a git submodule. Upstream does not ship a
+	# pkg-config file so we don't install one. Work around this using symlinks.
+	mkdir subprojects/stb || die
+	ln -sn "${ESYSROOT}"/usr/include/stb/* "${S}"/subprojects/packagefiles/stb/* subprojects/stb/ || die
+
+	# Normally uses vkroots from a git submodule. Upstream ships a Meson file
+	# that is sourced by this project. Create a symlink to it.
+	rm -r subprojects/vkroots || die
+	ln -sn "${ESYSROOT}"/usr/include/vkroots subprojects/ || die
+}
+
+src_configure() {
+	local emesonargs=(
+		--force-fallback-for=
+		$(meson_feature pipewire)
+	)
+	meson_src_configure
+}
-- 
cgit v1.2.3-65-gdbad