From 7ab539b3e6c6e1649763b31fea6ff0c8d54915e5 Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Sat, 22 Apr 2023 10:12:06 +0200
Subject: kde-apps/kget: 23.04.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 kde-apps/kget/Manifest            |  1 +
 kde-apps/kget/kget-23.04.0.ebuild | 78 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 79 insertions(+)
 create mode 100644 kde-apps/kget/kget-23.04.0.ebuild

(limited to 'kde-apps/kget')

diff --git a/kde-apps/kget/Manifest b/kde-apps/kget/Manifest
index 2a04cd485be5..cfdf1c4ad9c2 100644
--- a/kde-apps/kget/Manifest
+++ b/kde-apps/kget/Manifest
@@ -1 +1,2 @@
 DIST kget-22.12.3.tar.xz 5563272 BLAKE2B f05f1e2e69a9b55aad520ce933a8ec9e2f1819f7403ee9a6a4d13d57a24880a676261029950fde01544d51f5a3b8193e39813078da569854fcbf66d7280b1318 SHA512 0aa98f294766fae41a3d84d99962d5968da8365921f9c89b441c6b5cbd85726d493d7f467887e5f3b8e3127ce5cc24767f44b52d067be786677fd0c65628151c
+DIST kget-23.04.0.tar.xz 5561012 BLAKE2B 2d998b9de51edb64911333eae628ea66820df01d4c1998a161e97245be3998394c9ee282213e3d45ab08aac50539153a573e15953fa2d0ff63b392589c59ed1d SHA512 30b3d9caeb438f4787c1ffa2ebbf152513c4b2136f4431602f933bb7ca137c621b1845e8ad603b226e1acdae29e50b6b8eebad918990b8067e4e3ccacc7920ab
diff --git a/kde-apps/kget/kget-23.04.0.ebuild b/kde-apps/kget/kget-23.04.0.ebuild
new file mode 100644
index 000000000000..3684967a5a37
--- /dev/null
+++ b/kde-apps/kget/kget-23.04.0.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="forceoptional"
+KFMIN=5.104.0
+QTMIN=5.15.5
+VIRTUALX_REQUIRED="test"
+inherit ecm gear.kde.org
+
+DESCRIPTION="Advanced download manager by KDE"
+HOMEPAGE="https://apps.kde.org/kget/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="bittorrent gpg kde mms sqlite"
+
+RDEPEND="
+	>=app-crypt/qca-2.3.0:2[qt5(+)]
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwallet-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	bittorrent? ( >=net-libs/libktorrent-21.07.80:5 )
+	gpg? ( app-crypt/gpgme:=[qt5] )
+	kde? ( kde-plasma/libkworkspace:5 )
+	mms? ( media-libs/libmms )
+	sqlite? ( dev-db/sqlite:3 )
+"
+DEPEND="${RDEPEND}
+	dev-libs/boost
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package bittorrent KF5Torrent)
+		$(cmake_use_find_package gpg Gpgmepp)
+		$(cmake_use_find_package kde LibKWorkspace)
+		$(cmake_use_find_package mms LibMms)
+		$(cmake_use_find_package sqlite SQLite3)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	# bug 756817: schedulertest fails, see also upstream commit 45735cfa
+	# filedeletertest hangs.
+	local myctestargs=(
+		-E "(schedulertest|filedeletertest)"
+	)
+
+	ecm_src_test
+}
-- 
cgit v1.2.3-65-gdbad