From 5ad395b0eec8bb1e8b0ba502a77b14d9bb93c074 Mon Sep 17 00:00:00 2001
From: Andrew Ammerlaan <andrewammerlaan@gentoo.org>
Date: Fri, 5 Jul 2024 14:09:29 +0200
Subject: media-libs/oneVPL-cpu: drop USE flag "experimental"

Signed-off-by: Andrew Ammerlaan <andrewammerlaan@gentoo.org>
---
 media-libs/oneVPL-cpu/metadata.xml                 |  1 -
 .../oneVPL-cpu/oneVPL-cpu-2023.2.0-r1.ebuild       | 56 +++++++++++++++++++++
 media-libs/oneVPL-cpu/oneVPL-cpu-2023.2.0.ebuild   | 57 ----------------------
 3 files changed, 56 insertions(+), 58 deletions(-)
 create mode 100644 media-libs/oneVPL-cpu/oneVPL-cpu-2023.2.0-r1.ebuild
 delete mode 100644 media-libs/oneVPL-cpu/oneVPL-cpu-2023.2.0.ebuild

(limited to 'media-libs/oneVPL-cpu')

diff --git a/media-libs/oneVPL-cpu/metadata.xml b/media-libs/oneVPL-cpu/metadata.xml
index d738daf38bf1..567e19798957 100644
--- a/media-libs/oneVPL-cpu/metadata.xml
+++ b/media-libs/oneVPL-cpu/metadata.xml
@@ -12,7 +12,6 @@
 		<remote-id type="github">oneapi-src/oneVPL-cpu</remote-id>
 	</upstream>
 	<use>
-		<flag name="experimental">Enable experimental API</flag>
 		<flag name="openh264">Use <pkg>media-libs/openh264</pkg> instead of <pkg>media-libs/x264</pkg></flag>
 	</use>
 </pkgmetadata>
diff --git a/media-libs/oneVPL-cpu/oneVPL-cpu-2023.2.0-r1.ebuild b/media-libs/oneVPL-cpu/oneVPL-cpu-2023.2.0-r1.ebuild
new file mode 100644
index 000000000000..49321fe3ecae
--- /dev/null
+++ b/media-libs/oneVPL-cpu/oneVPL-cpu-2023.2.0-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="oneAPI Video Processing Library CPU implementation"
+HOMEPAGE="https://github.com/oneapi-src/oneVPL-cpu"
+SRC_URI="https://github.com/oneapi-src/oneVPL-cpu/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT x264? ( GPL-2 )"
+SLOT="0"
+KEYWORDS="~amd64"
+
+IUSE="openh264 test +x264"
+REQUIRED_USE="^^ ( openh264 x264 )"
+# RESTRICT="!test? ( test )"
+# Tests fail
+RESTRICT="test"
+
+BDEPEND="virtual/pkgconfig"
+DEPEND="
+	media-libs/dav1d
+	media-libs/libvpl
+	media-libs/svt-av1
+	media-libs/svt-hevc
+	media-video/ffmpeg
+	x264? ( media-libs/x264 )
+	openh264? ( media-libs/openh264 )
+"
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-2022.2.5-use-system-libs.patch"
+	"${FILESDIR}/${PN}-2022.2.5-respect-user-flags.patch"
+)
+
+src_configure() {
+	# Use system libraries
+	export VPL_BUILD_DEPENDENCIES="${ESYSROOT}/usr"
+	local mycmakeargs=(
+		-DBUILD_OPENH264="$(usex openh264)"
+		-DBUILD_TESTS="$(usex test)"
+		-DBUILD_GPL_X264="$(usex x264)"
+		# Use FHS instead
+		-DUSE_ONEAPI_INSTALL_LAYOUT=NO
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	# Remove these license files
+	rm -r "${ED}/usr/share/oneVPL-cpu/licensing" || die
+}
diff --git a/media-libs/oneVPL-cpu/oneVPL-cpu-2023.2.0.ebuild b/media-libs/oneVPL-cpu/oneVPL-cpu-2023.2.0.ebuild
deleted file mode 100644
index 4af580c27324..000000000000
--- a/media-libs/oneVPL-cpu/oneVPL-cpu-2023.2.0.ebuild
+++ /dev/null
@@ -1,57 +0,0 @@
-# Copyright 2022-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit cmake
-
-DESCRIPTION="oneAPI Video Processing Library CPU implementation"
-HOMEPAGE="https://github.com/oneapi-src/oneVPL-cpu"
-SRC_URI="https://github.com/oneapi-src/oneVPL-cpu/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="MIT x264? ( GPL-2 )"
-SLOT="0"
-KEYWORDS="~amd64"
-
-IUSE="experimental openh264 test +x264"
-REQUIRED_USE="^^ ( openh264 x264 )"
-# RESTRICT="!test? ( test )"
-# Tests fail
-RESTRICT="test"
-
-BDEPEND="virtual/pkgconfig"
-DEPEND="
-	media-libs/dav1d
-	media-libs/libvpl[experimental(-)?]
-	media-libs/svt-av1
-	media-libs/svt-hevc
-	media-video/ffmpeg
-	x264? ( media-libs/x264 )
-	openh264? ( media-libs/openh264 )
-"
-RDEPEND="${DEPEND}"
-
-PATCHES=(
-	"${FILESDIR}/${PN}-2022.2.5-use-system-libs.patch"
-	"${FILESDIR}/${PN}-2022.2.5-respect-user-flags.patch"
-)
-
-src_configure() {
-	# Use system libraries
-	export VPL_BUILD_DEPENDENCIES="${ESYSROOT}/usr"
-	local mycmakeargs=(
-		-DUSE_EXPERIMENTAL_API="$(usex experimental)"
-		-DBUILD_OPENH264="$(usex openh264)"
-		-DBUILD_TESTS="$(usex test)"
-		-DBUILD_GPL_X264="$(usex x264)"
-		# Use FHS instead
-		-DUSE_ONEAPI_INSTALL_LAYOUT=NO
-	)
-	cmake_src_configure
-}
-
-src_install() {
-	cmake_src_install
-	# Remove these license files
-	rm -r "${ED}/usr/share/oneVPL-cpu/licensing" || die
-}
-- 
cgit v1.2.3-65-gdbad