blob: 54434e12ad55bc196773526e01f7b03bef9dbcfa (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
LUA_COMPAT=( lua5-{1..3} luajit )
inherit cmake lua-single pax-utils systemd tmpfiles
if [[ ${PV} == *9999 ]] ; then
EGIT_REPO_URI="https://github.com/rspamd/rspamd.git"
inherit git-r3
else
SRC_URI="https://github.com/rspamd/rspamd/archive/${PV}.tar.gz -> ${P}.tar.gz"
KEYWORDS="~amd64 ~x86"
fi
DESCRIPTION="Rapid spam filtering system"
HOMEPAGE="https://rspamd.com https://github.com/rspamd/rspamd"
LICENSE="Apache-2.0 Boost-1.0 BSD BSD-1 BSD-2 CC0-1.0 LGPL-3 MIT public-domain unicode ZLIB"
SLOT="0"
IUSE="blas cpu_flags_x86_ssse3 jemalloc +jit pcre2 test"
RESTRICT="!test? ( test )"
# A part of tests use ffi luajit extension
REQUIRED_USE="${LUA_REQUIRED_USE}
test? ( lua_single_target_luajit )"
RDEPEND="${LUA_DEPS}
$(lua_gen_cond_dep '
dev-lua/LuaBitOp[${LUA_USEDEP}]
')
acct-group/rspamd
acct-user/rspamd
app-arch/zstd:=
dev-db/sqlite:3
dev-cpp/doctest
dev-libs/glib:2
dev-libs/icu:=
dev-libs/libev
dev-libs/libfmt:=
dev-libs/libsodium:=
dev-libs/snowball-stemmer:=
sys-apps/file
blas? (
virtual/blas
virtual/lapack
)
cpu_flags_x86_ssse3? ( dev-libs/hyperscan )
jemalloc? ( dev-libs/jemalloc:= )
dev-libs/openssl:0=[-bindist(-)]
pcre2? ( dev-libs/libpcre2:=[jit=] )
!pcre2? ( dev-libs/libpcre[jit=] )"
DEPEND="${RDEPEND}"
BDEPEND="
dev-util/ragel
virtual/pkgconfig
"
PATCHES=(
"${FILESDIR}/${P}-cmake-lua-version.patch"
"${FILESDIR}/${P}-system-libfmt.patch"
"${FILESDIR}/${P}-system-doctest.patch"
"${FILESDIR}/${P}-fix-null-dereference.patch"
"${FILESDIR}/${PN}-2.6-unbundle-lua.patch"
"${FILESDIR}/${PN}-2.5-unbundle-snowball.patch"
)
src_prepare() {
cmake_src_prepare
rm -vrf contrib/{doctest,fmt,lua-bit,snowball,zstd} || die
sed -i -e 's/User=_rspamd/User=rspamd/g' \
rspamd.service \
|| die
}
src_configure() {
local mycmakeargs=(
-DCONFDIR=/etc/rspamd
-DRUNDIR=/var/run/rspamd
-DDBDIR=/var/lib/rspamd
-DLOGDIR=/var/log/rspamd
-DSYSTEM_DOCTEST=ON
-DSYSTEM_FMT=ON
-DSYSTEM_ZSTD=ON
-DENABLE_BLAS=$(usex blas ON OFF)
-DENABLE_HYPERSCAN=$(usex cpu_flags_x86_ssse3 ON OFF)
-DENABLE_JEMALLOC=$(usex jemalloc ON OFF)
-DENABLE_LUAJIT=$(usex lua_single_target_luajit ON OFF)
-DENABLE_PCRE2=$(usex pcre2 ON OFF)
)
cmake_src_configure
}
src_test() {
cmake_build run-test
}
src_install() {
cmake_src_install
newconfd "${FILESDIR}"/rspamd.conf rspamd
newinitd "${FILESDIR}/rspamd-r7.init" rspamd
systemd_newunit rspamd.service rspamd.service
newtmpfiles "${FILESDIR}"/${PN}.tmpfile ${PN}.conf
# Remove mprotect for JIT support
if use lua_single_target_luajit; then
pax-mark m "${ED}"/usr/bin/rspamd-* "${ED}"/usr/bin/rspamadm-*
fi
insinto /etc/logrotate.d
newins "${FILESDIR}"/rspamd-r1.logrotate rspamd
diropts -o rspamd -g rspamd
keepdir /var/{lib,log}/rspamd
}
pkg_postinst() {
tmpfiles_process "${PN}.conf"
}
|
GitWeb