Fixed pump-mode issue.

Package-Manager: portage-2.2_rc12/cvs/Linux 2.6.27-gentoo x86_64

3 files changed, 161 insertions, 2 deletions

diff --git a/sys-devel/distcc/ChangeLog b/sys-devel/distcc/ChangeLog
index 3d2caa74919d..484a5eb86d29 100644
--- a/sys-devel/distcc/ChangeLog
+++ b/sys-devel/distcc/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sys-devel/distcc
 # Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-devel/distcc/ChangeLog,v 1.177 2008/10/25 06:39:17 matsuu Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-devel/distcc/ChangeLog,v 1.178 2008/10/26 06:44:04 matsuu Exp $
+
+*distcc-3.0-r3 (26 Oct 2008)
+
+  26 Oct 2008; MATSUU Takuto <matsuu@gentoo.org> +distcc-3.0-r3.ebuild:
+  Fixed pump-mode issue.
 
 *distcc-3.0-r2 (25 Oct 2008)
 
diff --git a/sys-devel/distcc/Manifest b/sys-devel/distcc/Manifest
index 393af618f7b1..eb1941b0ba08 100644
--- a/sys-devel/distcc/Manifest
+++ b/sys-devel/distcc/Manifest
@@ -25,5 +25,6 @@ EBUILD distcc-2.18.3-r11.ebuild 5684 RMD160 4e7232be695e39b41017bda3a1df5b5fa269
 EBUILD distcc-2.18.3-r12.ebuild 5639 RMD160 c70f35d9cf254d407a5d48688b09ce4f4ddc1271 SHA1 618ff9a60867cfdbd08f537ee35f41c28b9ce370 SHA256 d937b713f022bb4675ac1b1d0cdf0ae5a8ec683a523c3a5b9f948545cb960516
 EBUILD distcc-2.18.3-r13.ebuild 5686 RMD160 c875bd6c6260a61dbf487f53d7ac3f090e3f23c8 SHA1 5f17f8e6343fe2401f688090ddea3f5c183a8cf8 SHA256 fb5f9b7bb5230f8de7e87914abba720b2dc57940e27a0264e012fa39225bd843
 EBUILD distcc-3.0-r2.ebuild 3825 RMD160 5e7c1846d98736c8a10af706f19afb88a69a2c02 SHA1 25c07345bb7857f2f6353fa0e264be406087dba3 SHA256 7cedba3bb04269e64a0003ca231a37f4ed407fcb1d0e097f2e6566c70b3325a4
-MISC ChangeLog 33006 RMD160 c811ab1822bf8e2e10db5ed83bed0b7c59bc3691 SHA1 8a039e2ee2f5cc86b3d050173b0cad9001057af8 SHA256 53816ab93b40a4474cf5091842138ab517fdca5e79c55f6b0e7a9b3bf7ea3d75
+EBUILD distcc-3.0-r3.ebuild 4025 RMD160 1c636349a802e3311e73002f3d27596ce4062a5a SHA1 1a004e8d26f7fea3b606fa8d1cf0b091fdef0947 SHA256 0bbdcf9e909d4a6d23d5ac5c2b07b13723e28c8a8ef6b2ab4e62adaf0bf24d54
+MISC ChangeLog 33134 RMD160 28d6dd20c8e7e4a3da0dd1546b0851ef308f1caa SHA1 3ca11643e7a199ec9ad5620a9981e6ef56f517a5 SHA256 38111bdae755543b95b2bdd2a2ffce8d0a141aef8ecfe06ea5e9322b38c7d772
 MISC metadata.xml 375 RMD160 71766089deafcc906533d0dc537a46646f36b50a SHA1 c188ca1cdd4d1bc82f372608e8ad7fc473cb47e5 SHA256 adb92971f6939e55ce103e1c42d3ce3dfe82823d038db0e9cf9b08d9be888e1a
diff --git a/sys-devel/distcc/distcc-3.0-r3.ebuild b/sys-devel/distcc/distcc-3.0-r3.ebuild
new file mode 100644
index 000000000000..45069c5d1d08
--- /dev/null
+++ b/sys-devel/distcc/distcc-3.0-r3.ebuild
@@ -0,0 +1,153 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-devel/distcc/distcc-3.0-r3.ebuild,v 1.1 2008/10/26 06:44:04 matsuu Exp $
+
+inherit eutils fdo-mime flag-o-matic multilib toolchain-funcs
+
+DESCRIPTION="a program to distribute compilation of C code across several machines on a network"
+HOMEPAGE="http://distcc.org/"
+SRC_URI="http://distcc.googlecode.com/files/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="avahi gnome gtk ipv6 selinux xinetd"
+
+RESTRICT="test"
+
+RDEPEND=">=dev-lang/python-2.4
+	dev-libs/popt
+	avahi? ( >=net-dns/avahi-0.6 )
+	gnome? (
+		>=gnome-base/libgnome-2
+		>=gnome-base/libgnomeui-2
+		>=x11-libs/gtk+-2
+		x11-libs/pango
+	)
+	gtk? (
+		>=x11-libs/gtk+-2
+	)"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+RDEPEND="${RDEPEND}
+	!net-misc/pump
+	>=sys-devel/gcc-config-1.3.1
+	selinux? ( sec-policy/selinux-distcc )
+	xinetd? ( sys-apps/xinetd )"
+
+DCCC_PATH="/usr/$(get_libdir)/distcc/bin"
+
+pkg_setup() {
+	enewuser distcc 240 -1 -1 daemon
+}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	epatch "${FILESDIR}/${P}-gentoo.patch"
+	epatch "${FILESDIR}/${P}-svn617.patch"
+	sed -i -e "/PATH/s:\$distcc_location:${DCCC_PATH}:" pump.in || die
+}
+
+src_compile() {
+	# More legacy stuff?
+	[ "$(gcc-major-version)" = "2" ] && filter-lfs-flags
+
+	# -O? is required
+	[ "${CFLAGS/-O}" = "${CFLAGS}" ] && CFLAGS="${CFLAGS} -O2"
+
+	econf \
+		$(use_with avahi) \
+		$(use_with gtk) \
+		$(use_with gnome) \
+		$(use_enable ipv6 rfc2553) \
+		--with-docdir="/usr/share/doc/${PF}" || die "econf failed"
+	emake || die "emake failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+
+	dobin "${FILESDIR}/${PV}/distcc-config"
+
+	newinitd "${FILESDIR}/${PV}/init" distccd
+
+	cp "${FILESDIR}/${PV}/conf" "${T}/distccd"
+	if use avahi; then
+		cat >> "${T}/distccd" <<-EOF
+	
+		# Enable zeroconf support in distccd
+		DISTCCD_OPTS="\${DISTCCD_OPTS} --zeroconf"
+		EOF
+	fi
+	doconfd "${T}/distccd"
+
+	cat > "${T}/02distcc" <<-EOF
+	# This file is managed by distcc-config; use it to change these settings.'
+	DISTCC_LOG=""
+	DCCC_PATH="${DCCC_PATH}"
+	DISTCC_VERBOSE="0"
+	EOF
+	doenvd "${T}/02distcc"
+
+	# create the masquerade directory
+	dodir "${DCCC_PATH}"
+	for f in cc c++ gcc g++; do
+		dosym /usr/bin/distcc "${DCCC_PATH}/${f}"
+		if [ "${f}" != "cc" ]; then
+			dosym /usr/bin/distcc "${DCCC_PATH}/${CTARGET:-${CHOST}}-${f}"
+		fi
+	done
+
+	# create the distccd pid directory
+	keepdir /var/run/distccd
+	fowners distcc:daemon /var/run/distccd
+
+	if use gnome || use gtk; then
+	  einfo "Renaming /usr/bin/distccmon-gnome to /usr/bin/distccmon-gui"
+	  einfo "This is to have a little sensability in naming schemes between distccmon programs"
+	  mv "${D}/usr/bin/distccmon-gnome" "${D}/usr/bin/distccmon-gui" || die
+	  dosym distccmon-gui /usr/bin/distccmon-gnome
+	fi
+
+	if use xinetd; then
+		insinto /etc/xinetd.d
+		newins "${FILEDIR}/${PV}/xinetd"
+	fi
+
+	rm -rf "${D}/etc/default"
+	rm -f "${D}/etc/distcc/clients.allow"
+	rm -f "${D}/etc/distcc/commands.allow.sh"
+	prepalldocs
+}
+
+pkg_postinst() {
+	use gnome && fdo-mime_desktop_database_update
+
+	elog
+	elog "Tips on using distcc with Gentoo can be found at"
+	elog "http://www.gentoo.org/doc/en/distcc.xml"
+	elog
+	elog "How to use pump mode with Gentoo:"
+	elog "# distcc-config --set-host \"foo,cpp,lzo bar,cpp,lzo baz,cpp,lzo\""
+	elog "# pump emerge -u world"
+	elog
+	elog "To use the distccmon programs with Gentoo you should use this command:"
+	elog "# DISTCC_DIR=\"${DISTCC_DIR}\" distccmon-text 5"
+
+	if use gnome || use gtk; then
+		elog "Or:"
+		elog "# DISTCC_DIR=\"${DISTCC_DIR}\" distccmon-gnome"
+	fi
+
+	elog
+	elog "***SECURITY NOTICE***"
+	elog "If you are upgrading distcc please make sure to run etc-update to"
+	elog "update your /etc/conf.d/distccd and /etc/init.d/distccd files with"
+	elog "added security precautions (the --listen and --allow directives)"
+	elog
+}
+
+pkg_postrm() {
+	use gnome && fdo-mime_desktop_database_update
+}