blob: f4bb98b61f96d6b03abcad2dde1bd25409283c82 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
|
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-board/gnubg/gnubg-1.04.000.ebuild,v 1.7 2015/01/01 11:30:12 ago Exp $
EAPI=5
PYTHON_COMPAT=( python2_6 python2_7 )
inherit autotools eutils python-single-r1 gnome2-utils games
DESCRIPTION="GNU BackGammon"
HOMEPAGE="http://www.gnubg.org/"
SRC_URI="http://gnubg.org/media/sources/${PN}-release-${PV}-sources.tar.gz"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="amd64 ~arm ppc ppc64 x86 ~x86-fbsd"
IUSE="avx gtk opengl python sqlite3 sse sse2 threads"
RDEPEND="dev-libs/glib:2
media-libs/freetype:2
media-libs/libpng:0
x11-libs/cairo
x11-libs/pango
dev-db/sqlite:3
media-libs/libcanberra
dev-libs/libxml2
dev-libs/gmp:0
gtk? ( x11-libs/gtk+:2 )
opengl? (
x11-libs/gtk+:2
x11-libs/gtkglext
virtual/glu
)
sys-libs/readline
python? ( ${PYTHON_DEPS} )
media-fonts/dejavu
virtual/libintl"
DEPEND="${RDEPEND}
virtual/pkgconfig
sys-devel/gettext"
pkg_setup() {
games_pkg_setup
python-single-r1_pkg_setup
}
src_prepare() {
# use ${T} instead of /tmp for constructing credits (bug #298275)
sed -i -e 's:/tmp:${T}:' credits.sh || die
sed -i -e 's/fonts //' Makefile.in || die # handle font install ourself to fix bug #335774
sed -i \
-e '/^localedir / s#=.*$#= @localedir@#' \
-e '/^gnulocaledir / s#=.*$#= @localedir@#' \
po/Makefile.in.in || die
sed -i \
-e '/^gnubgiconsdir / s#=.*#= /usr/share#' \
-e '/^gnubgpixmapsdir / s#=.*#= /usr/share/pixmaps#' \
pixmaps/Makefile.in || die
}
src_configure() {
local simd=no
local gtk_arg=--without-gtk
if use gtk || use opengl ; then
gtk_arg=--with-gtk
fi
use sse && simd=sse
use sse2 && simd=sse2
use avx && simd=avx
egamesconf \
--localedir=/usr/share/locale \
--docdir=/usr/share/doc/${PF}/html \
--disable-cputest \
--enable-simd=${simd} \
${gtk_arg} \
$(use_enable threads) \
$(use_with python) \
$(use_with sqlite3 sqlite) \
$(use_with opengl board3d)
}
src_install() {
default
insinto "${GAMES_DATADIR}/${PN}"
doins ${PN}.weights *bd
dodir "${GAMES_DATADIR}"/${PN}/fonts
dosym /usr/share/fonts/dejavu/DejaVuSans.ttf "${GAMES_DATADIR}"/${PN}/fonts/Vera.ttf
dosym /usr/share/fonts/dejavu/DejaVuSans-Bold.ttf "${GAMES_DATADIR}"/${PN}/fonts/VeraBd.ttf
dosym /usr/share/fonts/dejavu/DejaVuSerif-Bold.ttf "${GAMES_DATADIR}"/${PN}/fonts/VeraSeBd.ttf
make_desktop_entry "gnubg -w" "GNU Backgammon"
prepgamesdirs
}
pkg_preinst() {
games_pkg_preinst
gnome2_icon_savelist
}
pkg_postinst() {
games_pkg_postinst
gnome2_icon_cache_update
}
pkg_postrm() {
gnome2_icon_cache_update
}
|
GitWeb