dev-db/spatialite: add 5.1.0

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 56 insertions, 0 deletions

diff --git a/dev-db/spatialite/Manifest b/dev-db/spatialite/Manifest
index b48579b5f199..e8acae8fd106 100644
--- a/dev-db/spatialite/Manifest
+++ b/dev-db/spatialite/Manifest
@@ -1 +1,2 @@
 DIST libspatialite-5.0.1.tar.gz 6372753 BLAKE2B 0fe5b37efac134e3796c96ed012b434ce99547037a44df69d3e98c7ac586c1173faa1fe93c4578e7cc0f47a9f1c539710661bad57f8012c3bdabde427221a842 SHA512 c2552994bc30d69d1e80aa274760f048cd384f71e8350a1e48a47cb8222ba71a1554a69c6534eedde9a09dc582c39c089967bcc1c57bf158cc91a3e7b1840ddf
+DIST libspatialite-5.1.0.tar.gz 6517377 BLAKE2B 871e2be82dd1f02de76f0755b6ea7a53797dd9905fe481d6f56dcf8a87278f0a9326a3e0662620cbf6bfe53f932dab199602885c7efcbc5a5e56781a7599d226 SHA512 2745b373e31cea58623224def6090c491b58409803bb71231450dfa2cfdf3aafc3fc6f680585d55d085008f8cf362c3062ae67ffc7d80257775a22eb81ef1e57
diff --git a/dev-db/spatialite/spatialite-5.1.0.ebuild b/dev-db/spatialite/spatialite-5.1.0.ebuild
new file mode 100644
index 000000000000..bf5f79f8f622
--- /dev/null
+++ b/dev-db/spatialite/spatialite-5.1.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="lib${PN}"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="A complete Spatial DBMS in a nutshell built upon sqlite"
+HOMEPAGE="https://www.gaia-gis.it/gaia-sins/"
+SRC_URI="https://www.gaia-gis.it/gaia-sins/${MY_PN}-sources/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MPL-1.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~x86"
+IUSE="+geos iconv +proj rttopo test +xls +xml"
+# Further poking required
+RESTRICT="test"
+
+RDEPEND="
+	>=dev-db/sqlite-3.7.5:3[extensions(+)]
+	sys-libs/zlib[minizip]
+	geos? ( >=sci-libs/geos-3.11.0 )
+	proj? ( sci-libs/proj:= )
+	xls? ( >=dev-libs/freexl-2.0.0 )
+	xml? ( dev-libs/libxml2 )
+	rttopo? ( sci-geosciences/librttopo )
+"
+DEPEND="${RDEPEND}"
+
+REQUIRED_USE="test? ( iconv )"
+
+src_configure() {
+	# 1) gcp disabled for now to preserve MPL licence
+	econf \
+		--disable-gcp \
+		--disable-examples \
+		--disable-static \
+		--enable-epsg \
+		$(use_enable rttopo) \
+		$(use_enable geos) \
+		$(use_enable geos geosadvanced) \
+		$(use_enable geos geos3100) \
+		$(use_enable geos geos3110) \
+		$(use_enable iconv) \
+		$(use_enable proj) \
+		$(use_enable xls freexl) \
+		$(use_enable xml libxml2)
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -delete || die
+}