dev-libs/appstream: 0.12.7 version bump

Package-Manager: Portage-2.3.67, Repoman-2.3.15
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 72 insertions, 0 deletions

diff --git a/dev-libs/appstream/Manifest b/dev-libs/appstream/Manifest
index bc0b7d0a17e4..47d00781da9d 100644
--- a/dev-libs/appstream/Manifest
+++ b/dev-libs/appstream/Manifest
@@ -1 +1,2 @@
 DIST AppStream-0.12.6.tar.xz 1953604 BLAKE2B 28b03a935b8c203f2ac2c52c1de8317cc899f2b81b00e83e2eb858dbd185a985ce608ba3f6b1c35f084b4ee91946a4870c89d6b0c0a4c6fd32a938558e3997f1 SHA512 c19cd89ba39aff5afa2ff6d5fca72581a8624463c33011b11036526db98392ff5aa6c0f599682e90fdee29b8732538cf96c20b66965016b96f60b3f899d722bb
+DIST AppStream-0.12.7.tar.xz 1958948 BLAKE2B 51a70395e4801ceeb3e97ac081f4c45be242cca14728f8efc5eec0d4b3cfa4cc9fab9ef7429c18e9bbb0dedb693a847258be1b11491155658a6ffa2a28358e35 SHA512 53ca7ebde3fcd345a895527da2ac5d829a09f25d28836a867b500282fba3465bde657cd75a4030cb831022f7a0d9f50aadb36078d62924e4d0edad6bfe3c5561
diff --git a/dev-libs/appstream/appstream-0.12.7.ebuild b/dev-libs/appstream/appstream-0.12.7.ebuild
new file mode 100644
index 000000000000..cbbde57065d8
--- /dev/null
+++ b/dev-libs/appstream/appstream-0.12.7.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson xdg-utils
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/ximion/${PN}"
+else
+	MY_PN="AppStream"
+	SRC_URI="https://www.freedesktop.org/software/appstream/releases/${MY_PN}-${PV}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+	S="${WORKDIR}/${MY_PN}-${PV}"
+fi
+
+DESCRIPTION="Cross-distro effort for providing metadata for software in the Linux ecosystem"
+HOMEPAGE="https://www.freedesktop.org/wiki/Distributions/AppStream/"
+
+LICENSE="LGPL-2.1+ GPL-2+"
+# check as_api_level
+SLOT="0/4"
+IUSE="apt +introspection qt5 test"
+
+BDEPEND="
+	app-text/docbook-xml-dtd:4.5
+	dev-libs/appstream-glib
+	dev-util/itstool
+	>=dev-util/meson-0.42.0
+	>=sys-devel/gettext-0.19.8
+	test? (
+		dev-qt/linguist-tools:5
+		qt5? ( dev-qt/qttest:5 )
+	)
+"
+DEPEND="
+	dev-db/lmdb:=
+	>=dev-libs/glib-2.54:2
+	dev-libs/libxml2:2
+	dev-libs/libyaml
+	dev-libs/snowball-stemmer
+	introspection? ( >=dev-libs/gobject-introspection-1.56:= )
+	qt5? ( dev-qt/qtcore:5 )
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	default
+	sed -e "/^as_doc_target_dir/s/appstream/${PF}/" -i docs/meson.build || die
+	if ! use test; then
+		sed -e "/^subdir.*tests/s/^/#DONT /" -i {,qt/}meson.build || die # bug 675944
+	fi
+}
+
+src_configure() {
+	xdg_environment_reset
+
+	local emesonargs=(
+		-Dapidocs=false
+		-Ddocs=false
+		-Dmaintainer=false
+		-Dstemming=true
+		-Dvapi=false
+		-Dapt-support=$(usex apt true false)
+		-Dgir=$(usex introspection true false)
+		-Dqt=$(usex qt5 true false)
+	)
+
+	meson_src_configure
+}