dev-python/pdm-backend: Bump to 2.2.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 70 insertions, 0 deletions

diff --git a/dev-python/pdm-backend/Manifest b/dev-python/pdm-backend/Manifest
index ee7d6238dd12..5bcdd73ed2a5 100644
--- a/dev-python/pdm-backend/Manifest
+++ b/dev-python/pdm-backend/Manifest
@@ -1 +1,2 @@
 DIST pdm-backend-2.1.8.gh.tar.gz 134738 BLAKE2B 5baf6db7193f27de5aa89e41852c714de7d2aa7fd9f75de9b1f1ebd455052bc9d9d47d95dbbed3436e9e9dae79c9a1d0ec54d71a4437036869de38aa035f0642 SHA512 975dad24d128a01b5484f62aece3b209eb3dddf3800c75e422ed1dd0d4cbe15ce60a155d6ed0cec4104eef47cad822e56a2379c877e3f5c8c719dfa86d8800c7
+DIST pdm-backend-2.2.0.gh.tar.gz 135965 BLAKE2B 7e4bfd68fb882caf91c0d7fe4164de9cb37b31ca158b25398a9c129edae42ad8a8ee811fd6819bda861b1412a44ea6c88b2b806b92b2a7bfaf531e947461be58 SHA512 8126b15852c25c27a70f6c39f9067b8617226648578f270c08f8030c2a9c181eb1a9162e17dc9d57a90268c2aad3f02120eb47bc8df674de1060e9de30a05e12
diff --git a/dev-python/pdm-backend/pdm-backend-2.2.0.ebuild b/dev-python/pdm-backend/pdm-backend-2.2.0.ebuild
new file mode 100644
index 000000000000..768d26b1dd72
--- /dev/null
+++ b/dev-python/pdm-backend/pdm-backend-2.2.0.ebuild
@@ -0,0 +1,69 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="A PEP 517 backend for PDM that supports PEP 621 metadata"
+HOMEPAGE="
+	https://pypi.org/project/pdm-backend/
+	https://github.com/pdm-project/pdm-backend/
+"
+SRC_URI="
+	https://github.com/pdm-project/pdm-backend/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+# see src/pdm/backend/_vendor/vendor.txt
+RDEPEND="
+	>=dev-python/packaging-24.0[${PYTHON_USEDEP}]
+	>=dev-python/pyproject-metadata-0.8.0_rc1[${PYTHON_USEDEP}]
+	>=dev-python/tomli-w-1.0.0[${PYTHON_USEDEP}]
+
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+	' 3.10)
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/setuptools[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)
+"
+# setuptools are used to build C extensions
+RDEPEND+="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	rm -r src/pdm/backend/_vendor || die
+	find -name '*.py' -exec sed \
+		-e 's:from pdm\.backend\._vendor\.:from :' \
+		-e 's:from pdm\.backend\._vendor ::' \
+		-e 's:import pdm\.backend\._vendor\.:import :' \
+		-i {} + || die
+	distutils-r1_src_prepare
+}
+
+src_compile() {
+	# this must not be set during src_test()
+	local -x PDM_BUILD_SCM_VERSION=${PV}
+	distutils-r1_src_compile
+}
+
+src_test() {
+	git config --global user.email "test@example.com" || die
+	git config --global user.name "Test User" || die
+	distutils-r1_src_test
+}