dev-qt/qtpositioning: add 5.15.11

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 41 insertions, 0 deletions

diff --git a/dev-qt/qtpositioning/qtpositioning-5.15.11.ebuild b/dev-qt/qtpositioning/qtpositioning-5.15.11.ebuild
new file mode 100644
index 000000000000..6718de2a8736
--- /dev/null
+++ b/dev-qt/qtpositioning/qtpositioning-5.15.11.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+QT5_MODULE="qtlocation"
+inherit qt5-build
+
+DESCRIPTION="Physical position determination library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+IUSE="geoclue +qml"
+
+RDEPEND="
+	=dev-qt/qtcore-${QT5_PV}*
+	geoclue? ( =dev-qt/qtdbus-${QT5_PV}* )
+	qml? ( =dev-qt/qtdeclarative-${QT5_PV}* )
+"
+DEPEND="${RDEPEND}"
+PDEPEND="
+	geoclue? ( app-misc/geoclue:2.0 )
+"
+
+QT5_TARGET_SUBDIRS=(
+	src/3rdparty/clipper
+	src/3rdparty/poly2tri
+	src/3rdparty/clip2tri
+	src/positioning
+	src/plugins/position/positionpoll
+)
+
+pkg_setup() {
+	use geoclue && QT5_TARGET_SUBDIRS+=( src/plugins/position/geoclue2 )
+	use qml && QT5_TARGET_SUBDIRS+=(
+		src/positioningquick
+		src/imports/positioning
+	)
+}