dev-tcltk/itk: fix install

Closes: https://bugs.gentoo.org/926110
Signed-off-by: Alfredo Tupone <tupone@gentoo.org>

1 files changed, 72 insertions, 0 deletions

diff --git a/dev-tcltk/itk/itk-4.2.3-r1.ebuild b/dev-tcltk/itk/itk-4.2.3-r1.ebuild
new file mode 100644
index 000000000000..cd62e1a40f6f
--- /dev/null
+++ b/dev-tcltk/itk/itk-4.2.3-r1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit virtualx
+
+MY_PV=${PN}-$(ver_rs 1- '-')
+
+DESCRIPTION="Object Oriented Enhancements for Tcl/Tk"
+HOMEPAGE="http://incrtcl.sourceforge.net/"
+SRC_URI="https://github.com/tcltk/${PN}/archive/refs/tags/${MY_PV}.tar.gz"
+
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="~amd64 ~arm64 ~ia64 ~ppc ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	>=dev-lang/tk-8.6:=
+	>=dev-tcltk/itcl-4.1"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+QA_CONFIG_IMPL_DECL_SKIP=(
+	stat64 # used to test for Large File Support
+)
+
+PATCHES=( "${FILESDIR}"/${P}-install.patch )
+
+UNINSTALL_IGNORE='/usr/lib.*/itk.*/library'
+
+src_prepare() {
+	sed 's:-pipe::g' -i configure || die
+	default
+	echo "unknown" > manifest.uuid
+}
+
+src_configure() {
+	local itcl_package=$(best_version dev-tcltk/itcl)
+	local itcl_version=${itcl_package#*/*-}
+	local ITCL_VERSION="${itcl_version%-*}"
+	source "${EPREFIX}"/usr/$(get_libdir)/itcl${ITCL_VERSION}*/itclConfig.sh || die
+	econf \
+		--with-tcl="${EPREFIX}"/usr/$(get_libdir) \
+		--with-tclinclude="${EPREFIX}"/usr/include \
+		--with-tk="${EPREFIX}"/usr/$(get_libdir) \
+		--with-tkinclude="${EPREFIX}"/usr/include \
+		--with-itcl="${ITCL_SRC_DIR}" \
+		--with-x
+}
+
+src_compile() {
+	emake CFLAGS_DEFAULT="${CFLAGS}"
+}
+
+src_test() {
+	virtx default
+}
+
+src_install() {
+	default
+
+	dodoc license.terms
+
+	cat >> "${T}"/34${PN} <<- EOF
+	LDPATH="${EPREFIX}/usr/$(get_libdir)/${PN}${MY_PV}/"
+	EOF
+	doenvd "${T}"/34${PN}
+	dosym . /usr/$(get_libdir)/${PN}${PV}/library
+}