gnome-extra/gnome-calculator: Version bump to 44_rc

Signed-off-by: Guillermo Joandet <gjoandet@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/30096
Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 76 insertions, 0 deletions

diff --git a/gnome-extra/gnome-calculator/Manifest b/gnome-extra/gnome-calculator/Manifest
index 11e45115d56b..1c72119691b7 100644
--- a/gnome-extra/gnome-calculator/Manifest
+++ b/gnome-extra/gnome-calculator/Manifest
@@ -1 +1,2 @@
 DIST gnome-calculator-43.0.1.tar.xz 1205840 BLAKE2B d3044efb5307505485dd55c3401d0c21cc379bcfc6fdd4f0285d093c05e76f9c167c5bd65bdf899c7f3aed892258b65538020a70e690eeb459147e6bea15a94b SHA512 94ec47a03dac017801e9c499aceb2f5f6fd1c79966657c79b123476dc7f3a4a2c3e179c80763e965207b58427157cd6e072260bd79ab98a39eb011cfe3ef7c72
+DIST gnome-calculator-44.rc.tar.xz 1073448 BLAKE2B d9a81c6f841cd9a386e452aacdc64cdf3b467eba38cc07a94a3cd854bf64de1a78b6927d9030ba2eba554a1f8b442014199da8011f0a068c903276572c81c288 SHA512 0afee2cc032bb899701ce1de1f6b6fdda5b690ca0cac6fc0fe1af7b03344ef1cf9f5df20c73d9322729e009e9de9944d3a8a76ee1ba1ed5475c8785c321543ea
diff --git a/gnome-extra/gnome-calculator/gnome-calculator-44_rc.ebuild b/gnome-extra/gnome-calculator/gnome-calculator-44_rc.ebuild
new file mode 100644
index 000000000000..e5b1cb6fe7c1
--- /dev/null
+++ b/gnome-extra/gnome-calculator/gnome-calculator-44_rc.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson vala virtualx xdg
+
+DESCRIPTION="A calculator application for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Calculator"
+SRC_URI="https://download.gnome.org/sources/${PN}/44/${PN}-44.rc.tar.xz"
+S="${WORKDIR}/${PN}-44.rc"
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="+introspection test"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+# gtksourceview vapi definitions in dev-lang/vala itself are too old, and newer vala removes them
+# altogether, thus we need them installed by gtksourceview[vala]
+RDEPEND="
+	>=dev-libs/glib-2.40.0:2
+	dev-libs/libxml2:2
+	net-libs/libsoup:3.0
+	>=dev-libs/libgee-0.20.0:0.8
+	dev-libs/mpc:=
+	dev-libs/mpfr:0=
+	>=gui-libs/gtk-4.4.1:4
+	>=gui-libs/libadwaita-1.2.0:1
+	>=gui-libs/gtksourceview-5.3.0:5
+	introspection? ( >=dev-libs/gobject-introspection-1.58:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-libs/appstream-glib
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	$(vala_depend)
+	net-libs/libsoup:3.0[vala]
+	gui-libs/gtksourceview:5[vala]
+	gui-libs/libhandy:1[vala]
+"
+
+src_prepare() {
+	default
+	vala_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		-Ddisable-ui=false
+		#-Dvala-version # doesn't do anything in 3.34
+		$(meson_use !introspection disable-introspection)
+		$(meson_use test ui-tests)
+		-Dgcalc=true
+		-Dgci=true
+		-Dapp=true
+		-Ddoc=false
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx dbus-run-session meson test -C "${BUILD_DIR}" || die 'tests failed'
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}