media-video/mkvtoolnix: version bump to 42.0.0

Closes: https://bugs.gentoo.org/704944
Signed-off-by: Tim Harder <radhermit@gentoo.org>

3 files changed, 122 insertions, 2 deletions

diff --git a/media-video/mkvtoolnix/Manifest b/media-video/mkvtoolnix/Manifest
index f8060cf05b4e..96fd2c949237 100644
--- a/media-video/mkvtoolnix/Manifest
+++ b/media-video/mkvtoolnix/Manifest
@@ -1 +1,2 @@
 DIST mkvtoolnix-37.0.0.tar.xz 7307984 BLAKE2B 4ee59d6ed186e7181733f5723fc8ab5abed5056c7562cf646b123f0e4d9e6b191176feab549231d8210b669d4cec36aaa6e33bf1b666b92ba471696d83e98c8e SHA512 196f8d12f36d95d077b8afeda4d651fe7fe5a0d6c9e71a49608732cbf6d68052681ec855875ed4a79e8aa0589502f4475a4306eaa9464523288a1af740b84df8
+DIST mkvtoolnix-42.0.0.tar.xz 7486620 BLAKE2B e364f2522013b3705484c5e0ad60600300ea82cc7b8bdc15d9e1f107329abd3b22a873d687328df8177a66eb7b6103fb89de62eb038d180d70dd16f5af155396 SHA512 2dfe267c6b9bc3c976637a18df3da04d7e82dd46d7134ab041959615f090afb2996eb2b15277f36cb257cac7cb5304451e131c0ec6aa608ff10c80c5fec9702a
diff --git a/media-video/mkvtoolnix/mkvtoolnix-42.0.0.ebuild b/media-video/mkvtoolnix/mkvtoolnix-42.0.0.ebuild
new file mode 100644
index 000000000000..6c3ac899f3d8
--- /dev/null
+++ b/media-video/mkvtoolnix/mkvtoolnix-42.0.0.ebuild
@@ -0,0 +1,119 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic toolchain-funcs multiprocessing qmake-utils xdg
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://gitlab.com/mbunkus/mkvtoolnix.git"
+	EGIT_SUBMODULES=()
+	inherit autotools git-r3
+else
+	SRC_URI="https://mkvtoolnix.download/sources/${P}.tar.xz"
+	KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+fi
+
+DESCRIPTION="Tools to create, alter, and inspect Matroska files"
+HOMEPAGE="https://mkvtoolnix.download/ https://gitlab.com/mbunkus/mkvtoolnix"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="debug nls pch test qt5"
+RESTRICT="!test? ( test )"
+
+# check NEWS.md for build system changes entries for boost/libebml/libmatroska
+# version requirement updates and other packaging info
+RDEPEND="
+	>=dev-libs/boost-1.60:=
+	>=dev-libs/libebml-1.3.7:=
+	>=dev-libs/libfmt-5.3.0:=
+	dev-libs/pugixml:=
+	media-libs/flac:=
+	>=media-libs/libmatroska-1.5.0:=
+	media-libs/libogg:=
+	media-libs/libvorbis:=
+	sys-apps/file
+	sys-libs/zlib
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtdbus:5
+		dev-qt/qtgui:5
+		dev-qt/qtnetwork:5
+		dev-qt/qtwidgets:5
+		dev-qt/qtconcurrent:5
+		dev-qt/qtmultimedia:5
+		app-text/cmark:0=
+	)
+"
+DEPEND="${RDEPEND}
+	dev-cpp/nlohmann_json
+	dev-libs/utfcpp
+	test? ( dev-cpp/gtest )
+"
+BDEPEND="
+	app-text/docbook-xsl-stylesheets
+	dev-libs/libxslt
+	dev-ruby/rake
+	virtual/pkgconfig
+	nls? (
+		sys-devel/gettext
+		app-text/po4a
+	)
+"
+
+src_prepare() {
+	xdg_src_prepare
+	if [[ ${PV} == *9999 ]]; then
+		./autogen.sh || die
+	fi
+
+	# remove bundled libs
+	rm -r lib/{fmt,libebml,libmatroska,nlohmann-json,pugixml,utf8-cpp} || die
+}
+
+src_configure() {
+	# bug 692322, use system dev-libs/utfcpp
+	append-cppflags -I"${ESYSROOT}"/usr/include/utf8cpp
+
+	local myeconfargs=(
+		$(use_enable debug)
+		$(usex pch "" --disable-precompiled-headers)
+		$(use_enable qt5 qt)
+		$(use_with nls gettext)
+		$(usex nls "" --with-po4a-translate=false)
+		--disable-update-check
+		--disable-optimization
+		--with-boost="${ESYSROOT}"/usr
+		--with-boost-libdir="${ESYSROOT}"/usr/$(get_libdir)
+	)
+
+	if use qt5 ; then
+		# ac/qt5.m4 finds default Qt version set by qtchooser, bug #532600
+		myeconfargs+=(
+			--with-moc=$(qt5_get_bindir)/moc
+			--with-uic=$(qt5_get_bindir)/uic
+			--with-rcc=$(qt5_get_bindir)/rcc
+			--with-qmake=$(qt5_get_bindir)/qmake
+		)
+	fi
+
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	rake V=1 -j$(makeopts_jobs) || die
+}
+
+src_test() {
+	rake V=1 -j$(makeopts_jobs) tests:unit || die
+	rake V=1 -j$(makeopts_jobs) tests:run_unit || die
+}
+
+src_install() {
+	DESTDIR="${D}" rake -j$(makeopts_jobs) install || die
+
+	einstalldocs
+	dodoc NEWS.md
+	doman doc/man/*.1
+}
diff --git a/media-video/mkvtoolnix/mkvtoolnix-9999.ebuild b/media-video/mkvtoolnix/mkvtoolnix-9999.ebuild
index 99b70cef63ea..6c3ac899f3d8 100644
--- a/media-video/mkvtoolnix/mkvtoolnix-9999.ebuild
+++ b/media-video/mkvtoolnix/mkvtoolnix-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2019 Gentoo Authors
+# Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -25,7 +25,7 @@ RESTRICT="!test? ( test )"
 # check NEWS.md for build system changes entries for boost/libebml/libmatroska
 # version requirement updates and other packaging info
 RDEPEND="
-	dev-libs/boost:=
+	>=dev-libs/boost-1.60:=
 	>=dev-libs/libebml-1.3.7:=
 	>=dev-libs/libfmt-5.3.0:=
 	dev-libs/pugixml:=