net-analyzer/yersinia: further Clang 16 fixes

Bug: https://bugs.gentoo.org/879719
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 62 insertions, 0 deletions

diff --git a/net-analyzer/yersinia/yersinia-0.8.2-r2.ebuild b/net-analyzer/yersinia/yersinia-0.8.2-r2.ebuild
new file mode 100644
index 000000000000..be2de6bbc614
--- /dev/null
+++ b/net-analyzer/yersinia/yersinia-0.8.2-r2.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools flag-o-matic
+
+DESCRIPTION="A framework for layer 2 attacks"
+HOMEPAGE="http://www.yersinia.net/"
+SRC_URI="https://github.com/tomac/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="gtk ncurses"
+
+RDEPEND="
+	>=net-libs/libnet-1.1.2
+	>=net-libs/libpcap-0.9.4
+	ncurses? ( >=sys-libs/ncurses-5.5:= )
+	gtk? (
+		dev-libs/glib:2
+		x11-libs/gdk-pixbuf
+		=x11-libs/gtk+-2*
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+DOCS=( AUTHORS ChangeLog FAQ README THANKS TODO )
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.7.1-no-ncurses.patch
+	"${FILESDIR}"/${PN}-0.7.3-tinfo.patch
+	"${FILESDIR}"/${PN}-0.8.2-configure-clang16.patch
+	"${FILESDIR}"/${PN}-0.8.2-configure-clang16-deux.patch
+)
+
+src_prepare() {
+	default
+
+	if ! use gtk; then
+		# bug #514802
+		sed -i -e '/AM_GLIB_GNU_GETTEXT/d' configure.in || die
+	fi
+
+	eautoreconf
+}
+
+src_configure() {
+	append-cflags -fcommon
+
+	econf \
+		--enable-admin \
+		--with-pcap-includes=/usr/include \
+		$(use_with ncurses) \
+		$(use_enable gtk)
+}
+
+src_compile() {
+	emake CFLAGS="${CFLAGS}"
+}