net-ftp/gproftpd: add missing libcrypt dependency

Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 58 insertions, 0 deletions

diff --git a/net-ftp/gproftpd/gproftpd-8.3.2-r3.ebuild b/net-ftp/gproftpd/gproftpd-8.3.2-r3.ebuild
new file mode 100644
index 000000000000..5c4a75116823
--- /dev/null
+++ b/net-ftp/gproftpd/gproftpd-8.3.2-r3.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="GTK frontend to proftpd"
+HOMEPAGE="https://mange.dynalias.org/linux/gproftpd"
+SRC_URI="http://mange.dynup.net/linux/gproftpd/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 ~ppc sparc x86"
+
+RDEPEND="
+	>=dev-libs/atk-1.0
+	>=media-libs/freetype-2.0
+	>=x11-libs/pango-1.0
+	dev-libs/glib:2
+	virtual/libcrypt:=
+	virtual/libiconv
+	x11-libs/gtk+:2
+"
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+PATCHES=(
+	"${FILESDIR}"/${P}-desktop.patch
+	"${FILESDIR}"/${P}-fno-common.patch
+	"${FILESDIR}"/${P}-install.patch
+)
+DOCS="AUTHORS ChangeLog README"
+
+src_prepare() {
+	default
+
+	mv configure.{in,ac} || die
+
+	eautoreconf
+}
+
+src_install() {
+	default
+
+	rm -r "${D}/usr/share/doc/gproftpd" || die
+}
+
+pkg_postinst() {
+	elog "gproftpd looks for your proftpd.conf file in /etc/proftpd"
+	elog "run gproftpd with the option -c to specify an alternate location"
+	elog "ex: gproftpd -c /etc/proftpd.conf"
+	elog "Do NOT edit /etc/conf.d/proftpd with this program"
+}