net-irc/konversation: 22.12.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 73 insertions, 0 deletions

diff --git a/net-irc/konversation/Manifest b/net-irc/konversation/Manifest
index 595bc48a35fb..e85533ec0944 100644
--- a/net-irc/konversation/Manifest
+++ b/net-irc/konversation/Manifest
@@ -1 +1,2 @@
 DIST konversation-22.08.3.tar.xz 4286292 BLAKE2B 69e8af19d16a16e01a4604d8dbfe4a8fda7659fa488470b97ed21a7e62d9d6ee558b25d90371c8524b72b8b46899c2aa3522f962a3bcc26928d0a9b24e73c63d SHA512 46be44918caf4992270cfff86281d5e84aef3596c3e08575efde087e8ee3a4586f75490cba4859fbe81ffbfd08b65722f2fce59cac6a745573049b2aa7e5a94b
+DIST konversation-22.12.0.tar.xz 4447324 BLAKE2B 2b005c72919762c9824c3601c2114b3dd6bffda7fc2ff5f92736e2c56f0ef4caee5b83ad99b7a8d7673ec905e0ffa7a2f22aced30e56c5be371fe735d375e9f8 SHA512 f8ab198c7a279e2865b4f0bec89cebbd9b8d9efdf5a4002e9a79159b420ba939618488227a124cb3350cb39be47b5cbaa9f39e96c3442d091d2b121373e5e2fb
diff --git a/net-irc/konversation/konversation-22.12.0.ebuild b/net-irc/konversation/konversation-22.12.0.ebuild
new file mode 100644
index 000000000000..34da70d30f40
--- /dev/null
+++ b/net-irc/konversation/konversation-22.12.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=5.99.0
+QTMIN=5.15.5
+inherit ecm gear.kde.org
+
+DESCRIPTION="User friendly IRC Client"
+HOMEPAGE="https://konversation.kde.org https://apps.kde.org/konversation/"
+
+LICENSE="GPL-2"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="+crypt"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtmultimedia-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kbookmarks-${KFMIN}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kidletime-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwallet-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	crypt? ( >=app-crypt/qca-2.3.0:2[qt5(+)] )
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtsvg-${QTMIN}:5
+	crypt? ( >=app-crypt/qca-2.3.0:2[qt5(+),ssl] )
+"
+BDEPEND="sys-devel/gettext"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package crypt Qca-qt5)
+	)
+
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+
+	# Bug 616162
+	insinto /etc/xdg
+	doins "${FILESDIR}"/konversationrc
+}