sys-cluster/cinder: PIKE

Package-Manager: Portage-2.3.6, Repoman-2.3.3

2 files changed, 211 insertions, 0 deletions

diff --git a/sys-cluster/cinder/Manifest b/sys-cluster/cinder/Manifest
index 8b955db0aabd..eb3d4ae80332 100644
--- a/sys-cluster/cinder/Manifest
+++ b/sys-cluster/cinder/Manifest
@@ -7,3 +7,4 @@ DIST newton-cinder.conf.sample 50793 SHA256 5179c86590fb5c9477ec838f1ccb8cd9c481
 DIST ocata-cinder-policy.json 6614 SHA256 992b4454d27cacf1c61c10d7c412b2b9673e798029c55747106c31f341bc8800 SHA512 6a3da28674e7bf828a2be8de0b41e6abe59567d0abf2a41781580ba611ca888e072960f3e702e834a1599e6bbb49beb1cd37f7a32e35afaf8dfc73f2852e2302 WHIRLPOOL a60659ee3007417a27dab2b4d4a7b75693b44f185107e951698bc3ae2b472777c8dc208bae1149c81ebf4288aabb37323bec07952105c7e560cec4d8bacf1a92
 DIST ocata-cinder-volume.filters 11067 SHA256 831d60708583b716376e6e68c69d1f5e7ce103010e7831b136fc332f62f84373 SHA512 9600ca77a63db04844ab9d658ffd0d97abe1c669d91f69d126b364b2700d749cd45d7df1e31ffd7e80698157e9267c3138cae098f36d77995bab73afdf32ff9f WHIRLPOOL a0d1bdcf9b36365cdd7c7acc6674bee41aaf1b57cdb35bc5972b9339ca8811e68200d50fa1821065582d0326fca5bf7e89b9c03cfeca77997845dd0a6a9571a8
 DIST ocata-cinder.conf.sample 173024 SHA256 995620f977f2d8ea479985b523824170769aeb2c80e255a1f29bab16e869977b SHA512 bbecf45ad20b3193023a137b5c3237dfc15bd6a232dda5de631096bf55916eb0fffba7506eeffdc1a3c848ac042cb286dea44387ff0eef84ec7bbcaffb4aa58e WHIRLPOOL 8a51471ec37dbe7211b9a0f87c855a34b8641993ed7b8d6c9ae633d2f58e8c112988421032730dbe3fed642de89d0cd2dd347247cc8aeca163134f5334fb68f2
+DIST pike-cinder.conf.sample 185310 SHA256 be8aa4e31f2854a100628188ea6536cd27788c4979b8072b98f35ac895ba9797 SHA512 12c44b7a31888fbf4c70e037a2f5d0b778018e10bd0fc1cb97391bbe2fc6f97bbe4bec0d1504513ee0235ce50decda6883fe64a7d8fd5e329d8ad73e6bb74654 WHIRLPOOL bcf799affb6c2b9adfd133b0630fb1cd4f4a185c3e1ed583d0610b3dc1160757d4a63766df7f2896eefb12a70f0544072a485ef62c8a59c1917eceb730029648
diff --git a/sys-cluster/cinder/cinder-2017.2.9999.ebuild b/sys-cluster/cinder/cinder-2017.2.9999.ebuild
new file mode 100644
index 000000000000..b470b8b2fc38
--- /dev/null
+++ b/sys-cluster/cinder/cinder-2017.2.9999.ebuild
@@ -0,0 +1,210 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 python3_{4,5} )
+
+inherit distutils-r1 eutils git-r3 linux-info user
+
+DESCRIPTION="Cinder is the OpenStack Block storage service, a spin out of nova-volumes"
+HOMEPAGE="https://launchpad.net/cinder"
+SRC_URI="https://dev.gentoo.org/~prometheanfire/dist/openstack/cinder/pike/cinder.conf.sample -> pike-cinder.conf.sample"
+EGIT_REPO_URI="https://github.com/openstack/cinder.git"
+EGIT_BRANCH="stable/pike"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS=""
+IUSE="+api +scheduler +volume infiniband iscsi lvm mysql +memcached postgres rdma sqlite +tcp test +tgt"
+REQUIRED_USE="|| ( mysql postgres sqlite ) iscsi? ( tgt ) infiniband? ( rdma )"
+
+CDEPEND=">=dev-python/pbr-2.0.0[${PYTHON_USEDEP}]
+	!~dev-python/pbr-2.1.0"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	${CDEPEND}
+	app-admin/sudo"
+
+RDEPEND="
+	${CDEPEND}
+	>=dev-python/Babel-2.3.4[${PYTHON_USEDEP}]
+	!~dev-python/Babel-2.4.0[${PYTHON_USEDEP}]
+	>=dev-python/decorator-3.4.0[${PYTHON_USEDEP}]
+	dev-python/enum34[$(python_gen_usedep 'python2_7')]
+	>=dev-python/eventlet-0.18.4[${PYTHON_USEDEP}]
+	!~dev-python/eventlet-0.20.1[${PYTHON_USEDEP}]
+	<dev-python/eventlet-0.21.0[${PYTHON_USEDEP}]
+	>=dev-python/greenlet-0.3.2[${PYTHON_USEDEP}]
+	>=dev-python/httplib2-0.7.5[${PYTHON_USEDEP}]
+	>=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
+	virtual/python-ipaddress[${PYTHON_USEDEP}]
+	>=dev-python/keystoneauth-3.1.0[${PYTHON_USEDEP}]
+	>=dev-python/keystonemiddleware-4.12.0[${PYTHON_USEDEP}]
+	>=dev-python/lxml-2.3[${PYTHON_USEDEP}]
+	!~dev-python/lxml-3.7.0[${PYTHON_USEDEP}]
+	>=dev-python/oauth2client-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-config-4.0.0[${PYTHON_USEDEP}]
+	!~dev-python/oslo-config-4.3.0[${PYTHON_USEDEP}]
+	!~dev-python/oslo-config-4.4.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-concurrency-3.8.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-context-2.14.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-db-4.24.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-log-3.22.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-messaging-5.24.2[${PYTHON_USEDEP}]
+	!~dev-python/oslo-messaging-5.25.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-middleware-3.27.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-policy-1.23.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-privsep-1.9.0[${PYTHON_USEDEP}]
+	!~dev-python/oslo-privsep-1.17.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-reports-0.6.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-rootwrap-5.0.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-serialization-1.10.0[${PYTHON_USEDEP}]
+	!~dev-python/oslo-serialization-2.19.1[${PYTHON_USEDEP}]
+	>=dev-python/oslo-service-1.10.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-3.20.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-versionedobjects-1.17.0[${PYTHON_USEDEP}]
+	>=dev-python/osprofiler-1.4.0[${PYTHON_USEDEP}]
+	>=dev-python/paramiko-2.0[${PYTHON_USEDEP}]
+	dev-python/paste[${PYTHON_USEDEP}]
+	>=dev-python/pastedeploy-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/psutil-3.2.2[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/python-barbicanclient-4.0.0[${PYTHON_USEDEP}]
+	!~dev-python/python-barbicanclient-4.5.0[${PYTHON_USEDEP}]
+	!~dev-python/python-barbicanclient-4.5.1[${PYTHON_USEDEP}]
+	>=dev-python/python-glanceclient-2.8.0[${PYTHON_USEDEP}]
+	>=dev-python/python-keystoneclient-3.8.0[${PYTHON_USEDEP}]
+	>=dev-python/python-novaclient-6.0.0[${PYTHON_USEDEP}]
+	!~dev-python/python-novaclient-7.0.0[${PYTHON_USEDEP}]
+	>=dev-python/python-swiftclient-3.2.0[${PYTHON_USEDEP}]
+	>=dev-python/pytz-2013.6[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.14.2[${PYTHON_USEDEP}]
+	>=dev-python/retrying-1.2.3[${PYTHON_USEDEP}]
+	!~dev-python/retrying-1.3.0[${PYTHON_USEDEP}]
+	>=dev-python/routes-2.3.1[${PYTHON_USEDEP}]
+	>=dev-python/taskflow-2.7.0[${PYTHON_USEDEP}]
+	>=dev-python/rtslib-fb-2.1.43[${PYTHON_USEDEP}]
+	!~dev-python/rtslib-fb-2.1.60[${PYTHON_USEDEP}]
+	!~dev-python/rtslib-fb-2.1.61[${PYTHON_USEDEP}]
+	>=dev-python/simplejson-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+	sqlite? (
+		>=dev-python/sqlalchemy-1.0.10[sqlite,${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.5[sqlite,${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.6[sqlite,${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.7[sqlite,${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.8[sqlite,${PYTHON_USEDEP}]
+	)
+	mysql? (
+		>=dev-python/pymysql-0.7.6[${PYTHON_USEDEP}]
+		!~dev-python/pymysql-0.7.7[${PYTHON_USEDEP}]
+		>=dev-python/sqlalchemy-1.0.10[${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.5[${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.6[${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.7[${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.8[${PYTHON_USEDEP}]
+	)
+	postgres? (
+		>=dev-python/psycopg-2.5.0[${PYTHON_USEDEP}]
+		>=dev-python/sqlalchemy-1.0.10[${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.5[${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.6[${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.7[${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-1.1.8[${PYTHON_USEDEP}]
+	)
+	>=dev-python/sqlalchemy-migrate-0.11.0[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-1.20.0[${PYTHON_USEDEP}]
+	~dev-python/suds-0.6[${PYTHON_USEDEP}]
+	>=dev-python/webob-1.7.1[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-2.1.0[${PYTHON_USEDEP}]
+	!~dev-python/oslo-i18n-3.15.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-vmware-2.17.0[${PYTHON_USEDEP}]
+	>=dev-python/os-brick-1.15.2[${PYTHON_USEDEP}]
+	>=dev-python/os-win-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/tooz-1.47.0[${PYTHON_USEDEP}]
+	>=dev-python/google-api-python-client-1.4.2[${PYTHON_USEDEP}]
+	>=dev-python/castellan-0.7.0[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-1.6[${PYTHON_USEDEP}]
+	!~dev-python/cryptography-2.0[${PYTHON_USEDEP}]
+	iscsi? (
+		tgt? ( sys-block/tgt )
+		sys-block/open-iscsi
+	)
+	lvm? ( sys-fs/lvm2 )
+	memcached? ( net-misc/memcached )
+	app-emulation/qemu
+	sys-fs/sysfsutils"
+# qemu is needed for image conversion
+
+#PATCHES=(
+#)
+
+pkg_pretend() {
+	linux-info_pkg_setup
+	CONFIG_CHECK_MODULES=""
+	if use tcp; then
+		CONFIG_CHECK_MODULES+="SCSI_ISCSI_ATTRS ISCSI_TCP "
+	fi
+	if use rdma; then
+		CONFIG_CHECK_MODULES+="INFINIBAND_ISER "
+	fi
+	if use infiniband; then
+		CONFIG_CHECK_MODULES+="INFINIBAND_IPOIB INFINIBAND_USER_MAD INFINIBAND_USER_ACCESS"
+	fi
+	if linux_config_exists; then
+		for module in ${CONFIG_CHECK_MODULES}; do
+			linux_chkconfig_present ${module} || ewarn "${module} needs to be enabled"
+		done
+	fi
+}
+
+pkg_setup() {
+	enewgroup cinder
+	enewuser cinder -1 -1 /var/lib/cinder cinder
+}
+
+python_prepare_all() {
+	sed -i '/^hacking/d' test-requirements.txt || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# Let's track progress of this # https://bugs.launchpad.net/swift/+bug/1249727
+	nosetests -I test_wsgi.py cinder/tests/ || die "tests failed under python2.7"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	keepdir /etc/cinder
+	dodir /etc/cinder/rootwrap.d
+
+	for svc in api scheduler volume; do
+		newinitd "${FILESDIR}/cinder.initd" cinder-${svc}
+	done
+
+	insinto /etc/cinder
+	insopts -m0640 -o cinder -g cinder
+	doins "etc/cinder/api-httpd.conf"
+	doins "etc/cinder/logging_sample.conf"
+	doins "etc/cinder/rootwrap.conf"
+	doins "etc/cinder/api-paste.ini"
+	doins "etc/cinder/policy.json"
+	doins "etc/cinder/resource_filters.json"
+	newins "${DISTDIR}/pike-cinder.conf.sample" "cinder.conf.sample"
+	insinto /etc/cinder/rootwrap.d
+	doins "etc/cinder/rootwrap.d/volume.filters"
+
+	dodir /var/log/cinder
+	fowners cinder:cinder /var/log/cinder
+
+	#add sudoers definitions for user nova
+	insinto /etc/sudoers.d/
+	insopts -m 0440 -o root -g root
+	newins "${FILESDIR}/cinder.sudoersd" cinder
+}
+
+pkg_postinst() {
+	if use iscsi ; then
+		elog "Cinder needs tgtd to be installed and running to work with iscsi"
+		elog "it also needs 'include /var/lib/cinder/volumes/*' in /etc/tgt/targets.conf"
+	fi
+}