www-client/opera: bump to 77.0.4054.277

Package-Manager: Portage-3.0.20, Repoman-3.0.2
Signed-off-by: Stephan Hartmann <sultan@gentoo.org>

2 files changed, 133 insertions, 0 deletions

diff --git a/www-client/opera/Manifest b/www-client/opera/Manifest
index 2322fbbd8908..b6ef7185bc80 100644
--- a/www-client/opera/Manifest
+++ b/www-client/opera/Manifest
@@ -1,2 +1,3 @@
 DIST opera-ffmpeg-codecs-91.0.4472.19.tar.xz 1383552 BLAKE2B f278bcef8ec013e24bb5293f50cb82be8b9381d181d6e837e8ed0f5b5f7fbdbde4d6e16e30787def46c333f2d6fb7573c7fbdf09697400d9429b3bc154a8da92 SHA512 58c419e469f257e5d3a7ec2fb18885a61aa8f4d6a56f8f6922fb4d4cecbfd9267d7cd72a451d1b23ee88bad0bebd83affa0850a1bbf7b2b26dac398752c7e905
 DIST opera-stable_77.0.4054.254_amd64.deb 76140556 BLAKE2B 38cab8d4ea3ccd3f0167a0912137e4839fed5db5a07313a98e4952bff24b9bf00fd27863e7fdc0932137311a5caf473e6582d7edf53a67731b0167cacf96e378 SHA512 2a97f69b2ca455ecc47d664ebed66c3b75ce4dfc8519782ef05b8bd8038c224bc2159b726874b514efe5a04ed0fce7024ce475c9ed3ac7253bccdd3c1d8abf5a
+DIST opera-stable_77.0.4054.277_amd64.deb 76233876 BLAKE2B a130d96215aba2b453f89ecfd4f6cb2f445be1994e46f2567f2cdf5c64fa80385371965465e7d8fa8f4c4571c8643fe737f42f6734086ab280e022d6d12c0e28 SHA512 0104ed6cb539ca7993286d21e2d4d8add2fa077bd7ca001e6b797838bccb9d2753b6a50a39146cec93e53cc1d2c9a609afc909160808f680fc225bc344555c46
diff --git a/www-client/opera/opera-77.0.4054.277.ebuild b/www-client/opera/opera-77.0.4054.277.ebuild
new file mode 100644
index 000000000000..ac62c3431ac4
--- /dev/null
+++ b/www-client/opera/opera-77.0.4054.277.ebuild
@@ -0,0 +1,132 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+CHROMIUM_LANGS="
+	be bg bn ca cs da de el en-GB en-US es-419 es fil fi fr-CA fr hi hr hu id
+	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+inherit chromium-2 multilib pax-utils unpacker xdg
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+LICENSE="OPERA-2018"
+SLOT="0"
+
+SRC_URI_BASE=(
+	"https://download1.operacdn.com/pub/${PN}"
+	"https://download2.operacdn.com/pub/${PN}"
+	"https://download3.operacdn.com/pub/${PN}"
+	"https://download4.operacdn.com/pub/${PN}"
+)
+
+if [[ ${PN} == opera ]]; then
+	MY_PN=${PN}-stable
+	SRC_URI_BASE=( "${SRC_URI_BASE[@]/%//desktop}" )
+else
+	MY_PN=${PN}
+fi
+
+KEYWORDS="-* ~amd64"
+
+FFMPEG_VERSION="91.0.4472.19"
+
+SRC_URI="${SRC_URI_BASE[@]/%//${PV}/linux/${MY_PN}_${PV}_amd64.deb}
+	proprietary-codecs? (
+		https://dev.gentoo.org/~sultan/distfiles/www-client/opera/opera-ffmpeg-codecs-${FFMPEG_VERSION}.tar.xz
+	)"
+
+IUSE="+proprietary-codecs suid"
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	app-accessibility/at-spi2-atk:2
+	app-accessibility/at-spi2-core:2
+	dev-libs/atk
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	gnome-base/gsettings-desktop-schemas
+	media-libs/alsa-lib
+	media-libs/mesa[gbm]
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/pango
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+OPERA_HOME="opt/opera${PN#opera}"
+
+pkg_pretend() {
+	# Protect against people using autounmask overzealously
+	use amd64 || die "opera only works on amd64"
+}
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	:
+}
+
+src_install() {
+	dodir /
+	cd "${ED}" || die
+	unpacker
+
+	# move to /opt, bug #573052
+	mkdir -p "${OPERA_HOME%${PN}}"
+	mv "usr/lib/x86_64-linux-gnu/${PN}" "${OPERA_HOME%${PN}}" || die
+	rm -r "usr/lib" || die
+
+	# disable auto update
+	rm "${OPERA_HOME}/${PN%-*}_autoupdate"{,.licenses,.version} || die
+
+	rm -r "usr/share/lintian" || die
+
+	# fix docs
+	mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
+	gzip -d usr/share/doc/${PF}/changelog.gz || die
+
+	# fix desktop file
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+
+	# remove unused language packs
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	# setup opera symlink
+	rm "usr/bin/${PN}" || die
+	dosym "../../${OPERA_HOME}/${PN}" "/usr/bin/${PN}"
+
+	# install proprietary codecs
+	rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
+	if use proprietary-codecs; then
+		mv lib_extra "${OPERA_HOME}"
+	fi
+
+	# pax mark opera, bug #562038
+	pax-mark m "${OPERA_HOME}/opera"
+	# enable suid sandbox if requested
+	use suid && fperms 4711 "${OPERA_HOME}/opera_sandbox"
+}