1 files changed, 43 insertions, 0 deletions
diff --git a/dev-libs/libindicator/libindicator-12.10.0-r200.ebuild b/dev-libs/libindicator/libindicator-12.10.0-r200.ebuild
new file mode 100644
index 000000000000..b95353bf4a8a
--- /dev/null
+++ b/dev-libs/libindicator/libindicator-12.10.0-r200.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=4
+inherit eutils flag-o-matic virtualx
+
+DESCRIPTION="A set of symbols and convience functions that all indicators would like to use"
+HOMEPAGE="http://launchpad.net/libindicator"
+SRC_URI="http://launchpad.net/${PN}/${PV%.*}/${PV}/+download/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+RDEPEND=">=dev-libs/glib-2.22
+	>=x11-libs/gtk+-2.18:2"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	test? ( dev-util/dbus-test-runner )"
+
+src_configure() {
+	append-flags -Wno-error
+
+	econf \
+		--disable-silent-rules \
+		--disable-static \
+		--with-gtk=2
+}
+
+src_test() {
+	Xemake check #391179
+}
+
+src_install() {
+	emake -j1 DESTDIR="${D}" install
+	prune_libtool_files --all
+
+	rm -vf \
+		"${ED}"/usr/lib*/libdummy-indicator-* \
+		"${ED}"/usr/share/${PN}/*indicator-debugging
+}