1 files changed, 50 insertions, 0 deletions
diff --git a/kde-apps/libkcddb/libkcddb-19.04.2.ebuild b/kde-apps/libkcddb/libkcddb-19.04.2.ebuild
new file mode 100644
index 000000000000..05aa44913966
--- /dev/null
+++ b/kde-apps/libkcddb/libkcddb-19.04.2.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_HANDBOOK="forceoptional"
+KDE_TEST="true"
+inherit kde5
+
+DESCRIPTION="KDE library for CDDB"
+LICENSE="GPL-2+ handbook? ( FDL-1.2 )"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="musicbrainz"
+
+DEPEND="
+	$(add_frameworks_dep kcodecs)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtnetwork)
+	$(add_qt_dep qtwidgets)
+	musicbrainz? ( media-libs/musicbrainz:5 )
+"
+RDEPEND="${DEPEND}"
+
+# tests require network access and compare static data with online data
+# bug 280996
+RESTRICT+=" test"
+
+src_prepare() {
+	kde5_src_prepare
+
+	if ! use handbook ; then
+		pushd kcmcddb > /dev/null
+		cmake_comment_add_subdirectory doc
+		popd > /dev/null
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package musicbrainz MusicBrainz5)
+	)
+
+	kde5_src_configure
+}