1 files changed, 53 insertions, 0 deletions
diff --git a/media-libs/libsidplay/libsidplay-2.1.1-r2.ebuild b/media-libs/libsidplay/libsidplay-2.1.1-r2.ebuild
new file mode 100644
index 000000000000..9f25f74ab914
--- /dev/null
+++ b/media-libs/libsidplay/libsidplay-2.1.1-r2.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=4
+inherit eutils libtool
+
+MY_P=sidplay-libs-${PV}
+
+DESCRIPTION="C64 SID player library"
+HOMEPAGE="http://sidplay2.sourceforge.net/"
+SRC_URI="mirror://sourceforge/sidplay2/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="2"
+KEYWORDS="alpha amd64 hppa ia64 ~mips ppc ppc64 sparc x86 ~x86-fbsd"
+IUSE="static-libs"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	epatch \
+		"${FILESDIR}"/${PN}2-gcc41.patch \
+		"${FILESDIR}"/${P}-fbsd.patch \
+		"${FILESDIR}"/${P}-gcc43.patch
+
+	elibtoolize
+}
+
+src_configure() {
+	econf \
+		--enable-shared \
+		$(use_enable static-libs static) \
+		--with-pic
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	docinto libsidplay
+	dodoc libsidplay/{AUTHORS,ChangeLog,README,TODO}
+
+	docinto libsidutils
+	dodoc libsidutils/{AUTHORS,ChangeLog,README,TODO}
+
+	docinto resid
+	dodoc resid/{AUTHORS,ChangeLog,NEWS,README,THANKS,TODO}
+
+	doenvd "${FILESDIR}"/65resid
+
+	# Libs: -line of libsidutils.pc and libsidplay2.pc reference .la files!
+	# find "${ED}" -name '*.la' -exec rm -f {} +
+}