3 files changed, 58 insertions, 0 deletions
diff --git a/net-libs/wslay/Manifest b/net-libs/wslay/Manifest
new file mode 100644
index 000000000000..664d4098dc5d
--- /dev/null
+++ b/net-libs/wslay/Manifest
@@ -0,0 +1 @@
+DIST wslay-1.1.1_p20210115.tar.gz 57514 BLAKE2B 1808814cf9cecc874f341989f14b36d53c9386681934f86547274dd9c926d1add84182960f02f0f2738e55723da17b99b16f046eea75ed1ec65be997d274ed21 SHA512 97fd58fba956162ebba8f824748ad3c161afb6a72e6e5db515f94a81edb99ddcd8eb332de4ffd08cb36f79010761036e4432e6d93b000ac5e4b0a88deeda9023
diff --git a/net-libs/wslay/metadata.xml b/net-libs/wslay/metadata.xml
new file mode 100644
index 000000000000..47029d119abf
--- /dev/null
+++ b/net-libs/wslay/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>ionen@gentoo.org</email>
+		<name>Ionen Wolkens</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">tatsuhiro-t/wslay</remote-id>
+	</upstream>
+</pkgmetadata>
diff --git a/net-libs/wslay/wslay-1.1.1_p20210115.ebuild b/net-libs/wslay/wslay-1.1.1_p20210115.ebuild
new file mode 100644
index 000000000000..4ddb9775de62
--- /dev/null
+++ b/net-libs/wslay/wslay-1.1.1_p20210115.ebuild
@@ -0,0 +1,46 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+WSLAY_HASH="45d22583b488f79d5a4e598cc7675c191c5ab53f"
+
+DESCRIPTION="WebSocket library in C"
+HOMEPAGE="https://tatsuhiro-t.github.io/wslay/"
+SRC_URI="https://github.com/tatsuhiro-t/wslay/archive/${WSLAY_HASH}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${WSLAY_HASH}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+DEPEND="test? ( dev-util/cunit )"
+BDEPEND="doc? ( dev-python/sphinx )"
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	local econfargs=(
+		# no options... and cmake build has different issues
+		$(usev !doc ac_cv_path_SPHINX_BUILD=)
+		$(usev !test ac_cv_lib_cunit_CU_initialize_registry=)
+		PKG_CONFIG=false # disables examples by failing to find nettle
+	)
+
+	econf "${econfargs[@]}"
+}
+
+src_install() {
+	local DOCS=( AUTHORS NEWS README.rst ) # skip non-rst README
+	default
+
+	find "${ED}" -type f -name '*.la' -delete || die
+}