From d76b148ac130c329531b4758a3b35648d89a263d Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Sun, 30 Dec 2018 19:56:10 +0100
Subject: dev-cpp/libcmis: 0.5.2 version bump

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 dev-cpp/libcmis/Manifest             |  1 +
 dev-cpp/libcmis/libcmis-0.5.2.ebuild | 66 ++++++++++++++++++++++++++++++++++++
 dev-cpp/libcmis/libcmis-9999.ebuild  | 20 ++++++-----
 3 files changed, 78 insertions(+), 9 deletions(-)
 create mode 100644 dev-cpp/libcmis/libcmis-0.5.2.ebuild

(limited to 'dev-cpp/libcmis')

diff --git a/dev-cpp/libcmis/Manifest b/dev-cpp/libcmis/Manifest
index 2e15c1774220..2065d178dde5 100644
--- a/dev-cpp/libcmis/Manifest
+++ b/dev-cpp/libcmis/Manifest
@@ -1,2 +1,3 @@
+DIST libcmis-0.5.2.tar.gz 295020 BLAKE2B 325eacedd87eb1888a439c727a648c5aeb8d58c9b80add9761ffc55381193b71b589865d13ecd55177faafa935642685001f60456c1354e037989b29e9451c05 SHA512 45d8cd6d420a9593b46e1f2d6fbf384ea248cb218b0db6326ee2f082ff29100b65a2cc999ccb849e61df4f4ed7c3721b09addc6c322ef03c6c93f8c0acc02bde
 DIST libcmis-0.5.2_pre20160820.tar.gz 285100 BLAKE2B 980200d1a56240d8d069aba2ad349ec02e90d345bad4956f6cbbea3606f9f90951523804293b349ad0419dd2db6db294a45a97872469105c1ba392c888fab332 SHA512 4b6d0fc4d80444fea2c5eb16621b92a10b41c58128cc8a355caca50f12648ed5113bd977cc5dbe8971e3dbc11f9d7ae8d45c9d2aa19f37c83659141af135bd1a
 DIST libcmis-0.5.2_pre20180118.tar.gz 291080 BLAKE2B 1cb5664dcb0bef7f5a04c422b21ac54a9b70d38dec74d688327732630e4a134a88c7262d763a39d1730eda1cd45f5d3c3d47a56099959d01bf5e23972181a793 SHA512 630cf7e5c31266e2b55ca093aa942fc373eb24bbb5b9aedd687f67f1b3c6b627a3bdb58878859449bcb340626f3e1bdafa2b9cbb5e61e8e4336c45b804fca7a9
diff --git a/dev-cpp/libcmis/libcmis-0.5.2.ebuild b/dev-cpp/libcmis/libcmis-0.5.2.ebuild
new file mode 100644
index 000000000000..2598ba450733
--- /dev/null
+++ b/dev-cpp/libcmis/libcmis-0.5.2.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+if [[ ${PV} = 9999 ]]; then
+	EGIT_REPO_URI="https://github.com/tdf/libcmis.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/tdf/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+fi
+inherit autotools flag-o-matic
+
+DESCRIPTION="C++ client library for the CMIS interface"
+HOMEPAGE="https://github.com/tdf/libcmis"
+
+LICENSE="|| ( GPL-2 LGPL-2 MPL-1.1 )"
+SLOT="0.5"
+
+IUSE="man static-libs test"
+
+RDEPEND="
+	dev-libs/boost:=
+	dev-libs/libxml2
+	net-misc/curl
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	man? (
+		app-text/docbook2X
+		dev-libs/libxslt
+	)
+	test? (
+		dev-util/cppcheck
+		dev-util/cppunit
+	)
+"
+
+RESTRICT="test"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	# bug 618778
+	append-cxxflags -std=c++14
+
+	local myeconfargs=(
+		--program-suffix=-$(ver_cut 1-2)
+		--disable-werror
+		$(use_with man)
+		$(use_enable static-libs static)
+		$(use_enable test tests)
+		--enable-client
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
diff --git a/dev-cpp/libcmis/libcmis-9999.ebuild b/dev-cpp/libcmis/libcmis-9999.ebuild
index 8513c4a8cb4f..33f9f92173ea 100644
--- a/dev-cpp/libcmis/libcmis-9999.ebuild
+++ b/dev-cpp/libcmis/libcmis-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -22,7 +22,7 @@ SLOT="0.5"
 
 # Don't move KEYWORDS on the previous line or ekeyword won't work # 399061
 [[ ${PV} == 9999 ]] || \
-KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86 ~amd64-linux ~x86-linux"
 
 IUSE="man static-libs test"
 
@@ -50,20 +50,22 @@ RESTRICT="test"
 
 src_prepare() {
 	default
-	[[ ${PV} = *_pre* || ${PV} = 9999 ]] && eautoreconf
+	eautoreconf
 }
 
 src_configure() {
 	# bug 618778
 	append-cxxflags -std=c++14
 
-	econf \
-		--program-suffix=-$(ver_cut 1-2) \
-		--disable-werror \
-		$(use_with man) \
-		$(use_enable static-libs static) \
-		$(use_enable test tests) \
+	local myeconfargs=(
+		--program-suffix=-$(ver_cut 1-2)
+		--disable-werror
+		$(use_with man)
+		$(use_enable static-libs static)
+		$(use_enable test tests)
 		--enable-client
+	)
+	econf "${myeconfargs[@]}"
 }
 
 src_install() {
-- 
cgit v1.2.3-65-gdbad