From 70e8d37416dd70bc56f21c23b5294091b4f46f97 Mon Sep 17 00:00:00 2001
From: Jakov Smolic <jakov.smolic@sartura.hr>
Date: Mon, 28 Dec 2020 16:17:04 +0100
Subject: dev-embedded/libftdi: Port to EAPI 7

* Disable static-libs
* Port to cmake eclass

Closes: https://bugs.gentoo.org/732476
Package-Manager: Portage-3.0.9, Repoman-3.0.1
Signed-off-by: Jakov Smolic <jakov.smolic@sartura.hr>
Signed-off-by: David Seifert <soap@gentoo.org>
---
 dev-embedded/libftdi/libftdi-1.4-r1.ebuild | 75 ++++++++++++++++++++++++++++++
 dev-embedded/libftdi/libftdi-1.4.ebuild    | 74 -----------------------------
 2 files changed, 75 insertions(+), 74 deletions(-)
 create mode 100644 dev-embedded/libftdi/libftdi-1.4-r1.ebuild
 delete mode 100644 dev-embedded/libftdi/libftdi-1.4.ebuild

(limited to 'dev-embedded/libftdi')

diff --git a/dev-embedded/libftdi/libftdi-1.4-r1.ebuild b/dev-embedded/libftdi/libftdi-1.4-r1.ebuild
new file mode 100644
index 000000000000..ff35d3bfef0c
--- /dev/null
+++ b/dev-embedded/libftdi/libftdi-1.4-r1.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} )
+inherit cmake python-single-r1
+
+if [[ ${PV} == 9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="git://developer.intra2net.com/${PN}"
+else
+	MY_P="${PN}1-${PV}"
+	SRC_URI="https://www.intra2net.com/en/developer/${PN}/download/${MY_P}.tar.bz2"
+	KEYWORDS="amd64 arm arm64 ~mips ppc ppc64 sparc x86"
+	S=${WORKDIR}/${MY_P}
+fi
+
+DESCRIPTION="Userspace access to FTDI USB interface chips"
+HOMEPAGE="https://www.intra2net.com/en/developer/libftdi/"
+
+LICENSE="LGPL-2"
+SLOT="1"
+IUSE="cxx doc examples python test tools"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	virtual/libusb:1
+	cxx? ( dev-libs/boost )
+	python? ( ${PYTHON_DEPS} )
+	tools? (
+		!<dev-embedded/ftdi_eeprom-1.0
+		dev-libs/confuse:=
+	)"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	doc? ( app-doc/doxygen )
+	python? ( dev-lang/swig )"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DFTDIPP=$(usex cxx)
+		-DDOCUMENTATION=$(usex doc)
+		-DEXAMPLES=$(usex examples)
+		-DPYTHON_BINDINGS=$(usex python)
+		-DBUILD_TESTS=$(usex test)
+		-DFTDI_EEPROM=$(usex tools)
+		-DSTATICLIBS=OFF
+		-DCMAKE_SKIP_BUILD_RPATH=ON
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	use python && python_optimize
+	dodoc AUTHORS ChangeLog README TODO
+
+	if use doc ; then
+		# Clean up crap man pages. #356369
+		rm -vf "${BUILD_DIR}"/doc/man/man3/_* || die
+
+		doman "${BUILD_DIR}"/doc/man/man3/*
+		dodoc -r "${BUILD_DIR}"/doc/html
+	fi
+	if use examples ; then
+		docinto examples
+		dodoc examples/*.c
+	fi
+}
diff --git a/dev-embedded/libftdi/libftdi-1.4.ebuild b/dev-embedded/libftdi/libftdi-1.4.ebuild
deleted file mode 100644
index 64b53c03c616..000000000000
--- a/dev-embedded/libftdi/libftdi-1.4.ebuild
+++ /dev/null
@@ -1,74 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-PYTHON_COMPAT=( python3_{6,7,8,9} )
-inherit cmake-utils python-single-r1
-
-MY_P="${PN}1-${PV}"
-if [[ ${PV} == 9999* ]] ; then
-	inherit git-r3
-	EGIT_REPO_URI="git://developer.intra2net.com/${PN}"
-else
-	SRC_URI="https://www.intra2net.com/en/developer/${PN}/download/${MY_P}.tar.bz2"
-	KEYWORDS="amd64 arm arm64 ~mips ppc ppc64 sparc x86"
-fi
-
-DESCRIPTION="Userspace access to FTDI USB interface chips"
-HOMEPAGE="https://www.intra2net.com/en/developer/libftdi/"
-
-LICENSE="LGPL-2"
-SLOT="1"
-IUSE="cxx doc examples python static-libs test tools"
-RESTRICT="!test? ( test )"
-REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
-
-RDEPEND="virtual/libusb:1
-	cxx? ( dev-libs/boost )
-	python? ( ${PYTHON_DEPS} )
-	tools? (
-		!<dev-embedded/ftdi_eeprom-1.0
-		dev-libs/confuse:=
-	)"
-DEPEND="${RDEPEND}
-	python? ( dev-lang/swig )
-	doc? ( app-doc/doxygen )"
-
-pkg_setup() {
-	use python && python-single-r1_pkg_setup
-}
-
-S=${WORKDIR}/${MY_P}
-
-src_configure() {
-	local mycmakeargs=(
-		-DFTDIPP=$(usex cxx)
-		-DDOCUMENTATION=$(usex doc)
-		-DEXAMPLES=$(usex examples)
-		-DPYTHON_BINDINGS=$(usex python)
-		-DSTATICLIBS=$(usex static-libs)
-		-DBUILD_TESTS=$(usex test)
-		-DFTDI_EEPROM=$(usex tools)
-		-DCMAKE_SKIP_BUILD_RPATH=ON
-	)
-	cmake-utils_src_configure
-}
-
-src_install() {
-	cmake-utils_src_install
-	use python && python_optimize
-	dodoc AUTHORS ChangeLog README TODO
-
-	if use doc ; then
-		# Clean up crap man pages. #356369
-		rm -vf "${CMAKE_BUILD_DIR}"/doc/man/man3/_* || die
-
-		doman "${CMAKE_BUILD_DIR}"/doc/man/man3/*
-		dodoc -r "${CMAKE_BUILD_DIR}"/doc/html
-	fi
-	if use examples ; then
-		docinto examples
-		dodoc examples/*.c
-	fi
-}
-- 
cgit v1.2.3-65-gdbad