From 5c99eebdb674acf940f95750395c7c09bfa08fe6 Mon Sep 17 00:00:00 2001
From: Joonas Niilola <juippis@gentoo.org>
Date: Sat, 19 Nov 2022 09:27:29 +0200
Subject: dev-libs/raft: add 0.16.0

Signed-off-by: Joonas Niilola <juippis@gentoo.org>
---
 dev-libs/raft/Manifest           |  1 +
 dev-libs/raft/raft-0.16.0.ebuild | 55 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 56 insertions(+)
 create mode 100644 dev-libs/raft/raft-0.16.0.ebuild

(limited to 'dev-libs/raft')

diff --git a/dev-libs/raft/Manifest b/dev-libs/raft/Manifest
index 680d7fac03f4..116a8b113953 100644
--- a/dev-libs/raft/Manifest
+++ b/dev-libs/raft/Manifest
@@ -1 +1,2 @@
 DIST raft-0.15.0.tar.gz 339309 BLAKE2B 2baf68b37d37af130e4530dbd97e15b17a4f609e00136284f07f0d16529c092abae875bae03a2bc0e68881662b41ecab945d200f33c0d4e66fe7e106f9d67a70 SHA512 273ad9385f6fe9a58824594d2ca84b879c1fa74ccef6a18e7077d097957956c10f3a12de7fe3b4500deba7910d8479345b6e086adfd1b7d577775be04af5306f
+DIST raft-0.16.0.tar.gz 347565 BLAKE2B 8452feed5bffefcc8087e62cdd48bda05be6a4068fbffcb0621779ab349902015be9095f252a253d6584faf4bfc6c8daefd97a130e7a9f8ef682ca03efd70dc0 SHA512 cee4a2f6fd9a0a16b591d46aa9df2104a50f2b62068eb27017e3347fc28a6b3cd3aef6bfabe3acc7e72844406b4b71aff1d1e088d08e83d6d2f5744876a681c8
diff --git a/dev-libs/raft/raft-0.16.0.ebuild b/dev-libs/raft/raft-0.16.0.ebuild
new file mode 100644
index 000000000000..dfebdcca2626
--- /dev/null
+++ b/dev-libs/raft/raft-0.16.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 2020-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="C implementation of the Raft consensus protocol"
+HOMEPAGE="https://github.com/canonical/raft"
+SRC_URI="https://github.com/canonical/raft/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-3-with-linking-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="lz4 test zfs"
+RESTRICT="!test? ( test )"
+
+DEPEND="dev-libs/libuv:=
+	lz4? ( app-arch/lz4:= )"
+RDEPEND="${DEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/raft-0.10.0-toggle-zfs.patch
+	"${FILESDIR}"/raft-0.11.3-disable-automagic-check-for-lz4.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-uv
+
+		--disable-benchmark
+		--disable-debug
+		--disable-example
+		--disable-sanitize
+		--disable-static
+
+		$(use_enable lz4)
+		$(use_enable test fixture)
+
+		$(use_with zfs)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3-65-gdbad