From e1fe6dbddbdc4a77da92d54a88d91735867126e6 Mon Sep 17 00:00:00 2001
From: Jeroen Roovers <jer@gentoo.org>
Date: Thu, 10 Oct 2019 09:36:59 +0200
Subject: dev-libs/dmalloc: EAPI=7

Package-Manager: Portage-2.3.76, Repoman-2.3.17
Signed-off-by: Jeroen Roovers <jer@gentoo.org>
---
 dev-libs/dmalloc/dmalloc-5.5.2-r7.ebuild | 83 ++++++++++++++++++++++++++++++++
 1 file changed, 83 insertions(+)
 create mode 100644 dev-libs/dmalloc/dmalloc-5.5.2-r7.ebuild

(limited to 'dev-libs')

diff --git a/dev-libs/dmalloc/dmalloc-5.5.2-r7.ebuild b/dev-libs/dmalloc/dmalloc-5.5.2-r7.ebuild
new file mode 100644
index 000000000000..4590fc50aa6c
--- /dev/null
+++ b/dev-libs/dmalloc/dmalloc-5.5.2-r7.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools multilib toolchain-funcs
+
+DESCRIPTION="A Debug Malloc Library"
+HOMEPAGE="http://dmalloc.com"
+SRC_URI="http://dmalloc.com/releases/${P}.tgz"
+
+LICENSE="CC-BY-SA-3.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE="static-libs threads"
+
+DEPEND="sys-apps/texinfo"
+DOCS=( NEWS README docs/NOTES docs/TODO )
+PATCHES=(
+	# - Build objects twice, once -fPIC for shared.
+	# - Use DESTDIR.
+	# - Fix SONAME and NEEDED.
+	"${FILESDIR}"/${P}-Makefile.in.patch
+	# - Broken test, always returns false.
+	"${FILESDIR}"/${P}-cxx.patch
+	"${FILESDIR}"/${P}-ar.patch
+	# strdup() strndup() macros
+	"${FILESDIR}"/${P}-string-macros.patch
+)
+
+src_prepare() {
+	default
+
+	# - Add threads support.
+	use threads && eapply "${FILESDIR}"/${P}-threads.patch
+
+	# Respect CFLAGS/LDFLAGS. #337429
+	sed -i \
+		-e '/libdmalloc/ s:$(CC):& $(CFLAGS) $(LDFLAGS):g' \
+		-e 's|ar cr|$(AR) cr|g' \
+		Makefile.in || die
+
+	# Run autoconf for -cxx.patch.
+	eautoconf
+}
+
+src_configure() {
+	tc-export AR
+	econf --enable-cxx --enable-shlib $(use_enable threads)
+}
+
+src_compile() {
+	default
+
+	cd docs
+	makeinfo dmalloc.texi || die
+}
+
+src_test() {
+	emake heavy
+}
+
+src_install() {
+	default
+
+	newdoc ChangeLog.1 ChangeLog
+	dodoc docs/dmalloc.pdf
+	dodoc RELEASE.html docs/dmalloc.html
+	doinfo docs/dmalloc.info
+
+	# add missing symlinks, lazy
+	dosym lib${PN}.so.${PV} /usr/$(get_libdir)/lib${PN}.so
+	dosym lib${PN}.so.${PV} /usr/$(get_libdir)/lib${PN}.so.${PV%%.*}
+
+	for lib in cxx th thcxx; do
+		dosym lib${PN}${lib}.so.${PV} /usr/$(get_libdir)/lib${PN}${lib}.so
+		dosym lib${PN}${lib}.so.${PV} \
+			/usr/$(get_libdir)/lib${PN}${lib}.so.${PV%%.*}
+	done
+
+	if ! use static-libs; then
+		rm "${ED}"/usr/$(get_libdir)/lib${PN}*.a || die
+	fi
+}
-- 
cgit v1.2.3-65-gdbad