From 4a5bbc56be51388752f4120902abbeafd798bda1 Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Thu, 1 Dec 2022 07:53:44 +0100
Subject: dev-python/python-dbusmock: Strip dbus-python requirement
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 .../python-dbusmock-0.28.6-r1.ebuild               | 42 ++++++++++++++++++++++
 .../python-dbusmock/python-dbusmock-0.28.6.ebuild  | 40 ---------------------
 2 files changed, 42 insertions(+), 40 deletions(-)
 create mode 100644 dev-python/python-dbusmock/python-dbusmock-0.28.6-r1.ebuild
 delete mode 100644 dev-python/python-dbusmock/python-dbusmock-0.28.6.ebuild

(limited to 'dev-python/python-dbusmock')

diff --git a/dev-python/python-dbusmock/python-dbusmock-0.28.6-r1.ebuild b/dev-python/python-dbusmock/python-dbusmock-0.28.6-r1.ebuild
new file mode 100644
index 000000000000..f50299fe3a38
--- /dev/null
+++ b/dev-python/python-dbusmock/python-dbusmock-0.28.6-r1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Easily create mock objects on D-Bus for software testing"
+HOMEPAGE="
+	https://github.com/martinpitt/python-dbusmock/
+	https://pypi.org/project/python-dbusmock/
+"
+SRC_URI="
+	https://github.com/martinpitt/python-dbusmock/releases/download/${PV}/${P}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="LGPL-3+"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ppc ppc64 ~riscv ~s390 sparc x86"
+
+RDEPEND="
+	dev-python/dbus-python[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# needed for unittest discovery
+	> tests/__init__.py || die
+	# linter tests, fragile to newer linter versions
+	rm tests/test_code.py || die
+	# dev-python/dbus-python uses autotools, so no .dist-info there
+	sed -i '/dbus-python/d' pyproject.toml setup.cfg || die
+
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/python-dbusmock/python-dbusmock-0.28.6.ebuild b/dev-python/python-dbusmock/python-dbusmock-0.28.6.ebuild
deleted file mode 100644
index 35d6a870d0c6..000000000000
--- a/dev-python/python-dbusmock/python-dbusmock-0.28.6.ebuild
+++ /dev/null
@@ -1,40 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{8..11} )
-PYTHON_REQ_USE="xml(+)"
-
-inherit distutils-r1
-
-DESCRIPTION="Easily create mock objects on D-Bus for software testing"
-HOMEPAGE="
-	https://github.com/martinpitt/python-dbusmock/
-	https://pypi.org/project/python-dbusmock/
-"
-SRC_URI="
-	https://github.com/martinpitt/python-dbusmock/releases/download/${PV}/${P}.tar.gz
-		-> ${P}.gh.tar.gz
-"
-
-LICENSE="LGPL-3+"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ppc ppc64 ~riscv ~s390 sparc x86"
-
-RDEPEND="
-	dev-python/dbus-python[${PYTHON_USEDEP}]
-	dev-python/pygobject:3[${PYTHON_USEDEP}]
-"
-
-distutils_enable_tests unittest
-
-src_prepare() {
-	# needed for unittest discovery
-	> tests/__init__.py || die
-	# linter tests, fragile to newer linter versions
-	rm tests/test_code.py || die
-
-	distutils-r1_src_prepare
-}
-- 
cgit v1.2.3-65-gdbad