From 75383b55eed8ef3ddfc01f2769ef9d0408ea5d5f Mon Sep 17 00:00:00 2001
From: Göktürk Yüksek <gokturk@gentoo.org>
Date: Tue, 17 Apr 2018 07:26:22 -0400
Subject: media-sound/playerctl: bump to 0.6.0

Package-Manager: Portage-2.3.19, Repoman-2.3.6
---
 media-sound/playerctl/playerctl-0.6.0.ebuild | 51 ++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 media-sound/playerctl/playerctl-0.6.0.ebuild

(limited to 'media-sound/playerctl/playerctl-0.6.0.ebuild')

diff --git a/media-sound/playerctl/playerctl-0.6.0.ebuild b/media-sound/playerctl/playerctl-0.6.0.ebuild
new file mode 100644
index 000000000000..ae41da21b7df
--- /dev/null
+++ b/media-sound/playerctl/playerctl-0.6.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools xdg-utils
+
+DESCRIPTION="A CLI utility to control media players over MPRIS"
+HOMEPAGE="https://github.com/acrisci/playerctl"
+SRC_URI="https://github.com/acrisci/playerctl/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+
+RDEPEND="
+	dev-libs/glib:2
+	dev-libs/gobject-introspection
+"
+DEPEND="${RDEPEND}
+	dev-util/gdbus-codegen
+	dev-util/gtk-doc-am
+	doc? ( dev-util/gtk-doc )
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	if ! use doc; then
+		echo 'EXTRA_DIST = ' > gtk-doc.make || die
+	fi
+
+	default
+	eautoreconf
+}
+
+src_configure() {
+	xdg_environment_reset # 596166
+
+	econf \
+		$(use_enable doc gtk-doc) \
+		$(use_enable doc gtk-doc-html)
+}
+
+src_compile() {
+	emake -j1
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3-65-gdbad