From 566d5c9a3acb9fb2c4ba7556a29f43f651be8a56 Mon Sep 17 00:00:00 2001
From: Maksym Chukhrii <cmvu@pm.me>
Date: Sun, 25 Jun 2023 23:17:38 +0300
Subject: net-vpn/networkmanager-openconnect: run eautoreconf before configure

Need to run autoreconf to regenerate configure script to apply changes from patch.

[sam: apply further fixups.]

Fixes: 5e64b2e22c37dbcb065c8e113fa22ecd7e86e2b2 (net-vpn/networkmanager-openconnect: Version bump to 1.2.10)
Closes: https://bugs.gentoo.org/906947
Signed-off-by: Maksym Chukhrii <cmvu@protonmail.com>
Closes: https://github.com/gentoo/gentoo/pull/31608
Signed-off-by: Sam James <sam@gentoo.org>
---
 .../networkmanager-openconnect-1.2.10-r1.ebuild    | 65 ++++++++++++++++++++++
 .../networkmanager-openconnect-1.2.10.ebuild       | 64 ---------------------
 2 files changed, 65 insertions(+), 64 deletions(-)
 create mode 100644 net-vpn/networkmanager-openconnect/networkmanager-openconnect-1.2.10-r1.ebuild
 delete mode 100644 net-vpn/networkmanager-openconnect/networkmanager-openconnect-1.2.10.ebuild

(limited to 'net-vpn')

diff --git a/net-vpn/networkmanager-openconnect/networkmanager-openconnect-1.2.10-r1.ebuild b/net-vpn/networkmanager-openconnect/networkmanager-openconnect-1.2.10-r1.ebuild
new file mode 100644
index 000000000000..2992e2b0a3ae
--- /dev/null
+++ b/net-vpn/networkmanager-openconnect/networkmanager-openconnect-1.2.10-r1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+GNOME2_EAUTORECONF=yes
+GNOME_ORG_MODULE="NetworkManager-${PN##*-}"
+
+inherit gnome2
+
+DESCRIPTION="NetworkManager OpenConnect plugin"
+HOMEPAGE="https://wiki.gnome.org/Projects/NetworkManager https://gitlab.gnome.org/GNOME/NetworkManager-openconnect"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="gtk"
+
+DEPEND="
+	>=net-misc/networkmanager-1.2:=
+	>=dev-libs/glib-2.34:2
+	>=dev-libs/dbus-glib-0.74
+	dev-libs/libxml2:2
+	dev-libs/glib:2
+	>=net-vpn/openconnect-3.02:=
+	gtk? (
+		>=app-crypt/libsecret-0.18
+
+		>=app-crypt/gcr-3.4:0=
+		>=x11-libs/gtk+-3.12:3
+
+		>=gui-libs/gtk-4.0:4
+		>=net-libs/libnma-1.8.36
+		net-libs/webkit-gtk:4.1
+	)
+"
+
+RDEPEND="
+	${DEPEND}
+	acct-group/nm-openconnect
+	acct-user/nm-openconnect
+"
+
+BDEPEND="
+	sys-devel/gettext
+	dev-util/intltool
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-check-webkit-if-gtk.patch
+)
+
+src_configure() {
+	local myconf=(
+		--disable-more-warnings
+		--disable-static
+		--without-libnm-glib
+		$(use_with gtk gnome)
+		$(use_with gtk authdlg)
+		$(use_with gtk gtk4)
+	)
+
+	gnome2_src_configure "${myconf[@]}"
+}
diff --git a/net-vpn/networkmanager-openconnect/networkmanager-openconnect-1.2.10.ebuild b/net-vpn/networkmanager-openconnect/networkmanager-openconnect-1.2.10.ebuild
deleted file mode 100644
index 0ee4f08b5ebe..000000000000
--- a/net-vpn/networkmanager-openconnect/networkmanager-openconnect-1.2.10.ebuild
+++ /dev/null
@@ -1,64 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-GNOME_ORG_MODULE="NetworkManager-${PN##*-}"
-
-inherit gnome2
-
-DESCRIPTION="NetworkManager OpenConnect plugin"
-HOMEPAGE="https://wiki.gnome.org/Projects/NetworkManager https://gitlab.gnome.org/GNOME/NetworkManager-openconnect"
-
-LICENSE="GPL-2+"
-SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
-IUSE="gtk"
-
-DEPEND="
-	>=net-misc/networkmanager-1.2:=
-	>=dev-libs/glib-2.34:2
-	>=dev-libs/dbus-glib-0.74
-	dev-libs/libxml2:2
-	dev-libs/glib:2
-	>=net-vpn/openconnect-3.02:=
-	gtk? (
-		>=app-crypt/libsecret-0.18
-
-		>=app-crypt/gcr-3.4:0=
-		>=x11-libs/gtk+-3.12:3
-
-		>=gui-libs/gtk-4.0:4
-		>=net-libs/libnma-1.8.36
-		net-libs/webkit-gtk:4.1
-	)
-"
-
-RDEPEND="
-	${DEPEND}
-	acct-group/nm-openconnect
-	acct-user/nm-openconnect
-"
-
-BDEPEND="
-	sys-devel/gettext
-	dev-util/intltool
-	virtual/pkgconfig
-"
-
-PATCHES+=(
-	"${FILESDIR}"/${P}-check-webkit-if-gtk.patch
-)
-
-src_configure() {
-	local myconf=(
-	gnome2_src_configure
-		--disable-more-warnings
-		--disable-static
-		--without-libnm-glib
-		$(use_with gtk gnome)
-		$(use_with gtk authdlg)
-		$(use_with gtk gtk4)
-	)
-	econf "${myconf[@]}"
-}
-- 
cgit v1.2.3-65-gdbad