blob: a9e0d81fb64b783fa0fe7148063595a3c5d5f6a2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
DESCRIPTION="A small and lightweight parser library for ATA S.M.A.R.T. hard disks"
HOMEPAGE="https://salsa.debian.org/utopia-team/libatasmart"
SRC_URI="mirror://debian/pool/main/liba/${PN}/${PN}_${PV/_p*}.orig.tar.xz
mirror://debian/pool/main/liba/${PN}/${PN}_${PV/_p/-}.debian.tar.xz"
LICENSE="LGPL-2.1"
SLOT="0/4"
KEYWORDS="alpha amd64 arm arm64 hppa ia64 ~mips ppc ppc64 ~sh sparc x86"
IUSE="static-libs"
RDEPEND="virtual/libudev:="
DEPEND="${RDEPEND}"
BDEPEND="
virtual/pkgconfig
"
S="${WORKDIR}/${P/_p*}"
src_prepare() {
# https://bugs.gentoo.org/470874
local d="${WORKDIR}/debian/patches"
sed -i -e '/#/d' \
-e "s|^|${d}/|" "${d}"/series || die
eapply $(<"${d}"/series)
eapply_user
}
src_configure() {
local myeconfargs=(
--docdir="${EPREFIX}"/usr/share/doc/${PF}
$(use_enable static-libs static)
)
econf "${myeconfargs[@]}"
}
src_install() {
default
find "${ED}" -type f -name "*.la" -delete || die
}
|
GitWeb
