blob: 70c6dfd46cfc73ab423421ac9491b61c287d73bd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
GNOME2_LA_PUNT="yes"
PYTHON_COMPAT=( python2_7 python3_{4,5} )
inherit eutils gnome2 python-r1 virtualx
DESCRIPTION="GLib's GObject library bindings for Python"
HOMEPAGE="https://wiki.gnome.org/Projects/PyGObject"
LICENSE="LGPL-2.1+"
SLOT="3"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
IUSE="+cairo examples test +threads"
REQUIRED_USE="
${PYTHON_REQUIRED_USE}
test? ( cairo )
"
COMMON_DEPEND="${PYTHON_DEPS}
>=dev-libs/glib-2.38:2
>=dev-libs/gobject-introspection-1.46.0:=
virtual/libffi:=
cairo? (
>=dev-python/pycairo-1.10.0[${PYTHON_USEDEP}]
x11-libs/cairo )
"
DEPEND="${COMMON_DEPEND}
virtual/pkgconfig
cairo? ( x11-libs/cairo[glib] )
test? (
dev-libs/atk[introspection]
media-fonts/font-cursor-misc
media-fonts/font-misc-misc
x11-libs/cairo[glib]
x11-libs/gdk-pixbuf:2[introspection]
x11-libs/gtk+:3[introspection]
x11-libs/pango[introspection]
python_targets_python2_7? ( dev-python/pyflakes[$(python_gen_usedep python2_7)] ) )
"
# gnome-base/gnome-common required by eautoreconf
# We now disable introspection support in slot 2 per upstream recommendation
# (see https://bugzilla.gnome.org/show_bug.cgi?id=642048#c9); however,
# older versions of slot 2 installed their own site-packages/gi, and
# slot 3 will collide with them.
RDEPEND="${COMMON_DEPEND}
!<dev-python/pygtk-2.13
!<dev-python/pygobject-2.28.6-r50:2[introspection]
"
src_prepare() {
# Test fail with xvfb but not X
sed -e 's/^.*TEST_NAMES=compat_test_pygtk .*;/echo "Test disabled";/' \
-i tests/Makefile.{am,in} || die
gnome2_src_prepare
python_copy_sources
}
src_configure() {
# Hard-enable libffi support since both gobject-introspection and
# glib-2.29.x rdepend on it anyway
# docs disabled by upstream default since they are very out of date
configuring() {
gnome2_src_configure \
$(use_enable cairo) \
$(use_enable threads thread)
# Pyflakes tests work only in python2, bug #516744
if use test && [[ ${EPYTHON} != python2.7 ]]; then
sed -e 's/if type pyflakes/if false/' \
-i Makefile || die "sed failed"
fi
}
python_foreach_impl run_in_build_dir configuring
}
src_compile() {
python_foreach_impl run_in_build_dir gnome2_src_compile
}
src_test() {
export GIO_USE_VFS="local" # prevents odd issues with deleting ${T}/.gvfs
export GIO_USE_VOLUME_MONITOR="unix" # prevent udisks-related failures in chroots, bug #449484
export SKIP_PEP8="yes"
testing() {
export XDG_CACHE_HOME="${T}/${EPYTHON}"
run_in_build_dir virtx emake check
unset XDG_CACHE_HOME
}
python_foreach_impl testing
unset GIO_USE_VFS
}
src_install() {
python_foreach_impl run_in_build_dir gnome2_src_install
dodoc -r examples
}
|
GitWeb